2.1 Standard note creation

The denote command will prompt for a title. If a region is active, the text of the region becomes the default at the minibuffer prompt (meaning that typing ‘RET’ without any input will use the default value). Once the title is supplied, the denote command will then ask for keywords. The resulting note will have a file name as already explained: The file naming scheme

The denote command runs the hook denote-after-new-note-hook after creating the new note.

The file type of the new note is determined by the user option denote-file-type (Front matter).

The keywords’ prompt supports minibuffer completion. Available candidates are those defined in the user option denote-known-keywords. More candidates can be inferred from the names of existing notes, by setting denote-infer-keywords to non-nil (which is the case by default).

Multiple keywords can be inserted by separating them with a comma (or whatever the value of the crm-separator is—which should be a comma). When the user option denote-sort-keywords is non-nil (the default), keywords are sorted alphabetically (technically, the sorting is done with string-lessp).

The interactive behaviour of the denote command is influenced by the user option denote-prompts (The denote-prompts option).

The denote command can also be called from Lisp. Read its doc string for the technicalities.

In the interest of discoverability, denote is also available under the alias denote-create-note.

• The denote-prompts option
• The denote-history-completion-in-prompts option
• The denote-templates option
• Convenience commands for note creation
• The denote-save-buffers option
• The denote-kill-buffers option
• The denote-date-prompt-use-org-read-date option

DATE--TITLE__KEYWORDS.EXT

DATE.EXT
DATE--TITLE.EXT
DATE__KEYWORDS.EXT

(setq denote-templates
      '((report . "* Some heading\n\n* Another heading")
        (memo . "* Some heading

* Another heading

")))

(setq denote-templates
      `((report . "* Some heading\n\n* Another heading")
        (memo . ,(concat "* Some heading"
                         "\n\n"
                         "* Another heading"
                         "\n\n"))))

(setq denote-templates
      `((report . "* Some heading\n\n* Another heading")
        (blog . my-denote-template-function-for-blog) ; a function to return a string
        (memo . ,(concat "* Some heading"
                         "\n\n"
                         "* Another heading"
                         "\n\n"))))

2.2 Create a note from the current Org subtree

In Org parlance, an entry with all its subheadings and other contents is a “subtree”. Denote can operate on the subtree to extract it from the current file and create a new file out of it. One such workflow is to collect thoughts in a single document and produce longer standalone notes out of them upon review.

The command denote-org-extras-extract-org-subtree is used for this purpose. It creates a new Denote note using the current Org subtree. In doing so, it removes the subtree from its current file and moves its contents into a new file. This command is part of the optional ‘denote-org-extras.el’ extension, which is part of the denote package. It is loaded automatically as soon as one of its commands is invoked.

The text of the subtree’s heading becomes the ‘#+title’ of the new note. Everything else is inserted as-is.

If the heading has any tags, they are used as the keywords of the new note. If the Org file has any ‘#+filetags’ they are taken as well (Org’s ‘#+filetags’ are inherited by the headings). If none of these are true and the user option denote-prompts includes an entry for keywords, then denote-org-extras-extract-org-subtree prompts for keywords. Else the new note has no keywords (Add or remove keywords interactively).

If the heading has a ‘PROPERTIES’ drawer, it is retained for further review.

If the heading’s ‘PROPERTIES’ drawer includes a ‘DATE’ or ‘CREATED’ property, or there exists a ‘CLOSED’ statement with a timestamp value, use that to derive the date (or date and time) of the new note (if there is only a date, the time is taken as 00:00). If more than one of these is present, the order of preference is ‘DATE’, then ‘CREATED’, then ‘CLOSED’. If none of these is present, the current time is used. If the denote-prompts includes an entry for a date, then the command prompts for a date at this stage (also see denote-date-prompt-use-org-read-date).

For the rest, it consults the value of the user option denote-prompts in the following scenaria:

• To optionally prompt for a subdirectory, otherwise it produces the new note in the denote-directory.
• To optionally prompt for a file signature, otherwise to not use any.

The new note is an Org file regardless of the user option denote-file-type.

2.3 Create note using Org capture

For integration with org-capture, the user must first add the relevant template. Such as:

(with-eval-after-load 'org-capture
  (add-to-list 'org-capture-templates
               '("n" "New note (with Denote)" plain
                 (file denote-last-path)
                 #'denote-org-capture
                 :no-save t
                 :immediate-finish nil
                 :kill-buffer t
                 :jump-to-captured t)))

[ In the future, we might develop Denote in ways which do not require such manual intervention. More user feedback is required to identify the relevant workflows. ]

Once the template is added, it is accessed from the specified key. If, for instance, org-capture is bound to ‘C-c c’, then the note creation is initiated with ‘C-c c n’, per the above snippet. After that, the process is the same as with invoking denote directly, namely: a prompt for a title followed by a prompt for keywords (Standard note creation).

Users may prefer to leverage org-capture in order to extend file creation with the specifiers described in the org-capture-templates documentation (such as to capture the active region and/or create a hyperlink pointing to the given context).

IMPORTANT. Due to the particular file-naming scheme of Denote, which is derived dynamically, such specifiers or other arbitrary text cannot be written directly in the template. Instead, they have to be assigned to the user option denote-org-capture-specifiers, which is interpreted by the function denote-org-capture. Example with our default value:

(setq denote-org-capture-specifiers "%l\n%i\n%?")

Note that denote-org-capture ignores the denote-file-type: it always sets the Org file extension for the created note to ensure that the capture process works as intended, especially for the desired output of the denote-org-capture-specifiers.

2.4 Create note with specific prompts using Org capture

This section assumes knowledge of how Denote+org-capture work, as explained in the previous section (Create note using Org capture).

The previous section shows how to define an Org capture template that always prompts for a title and keywords. There are, however, cases where the user wants more control over what kind of input Denote will prompt for. To this end, we provide the function denote-org-capture-with-prompts. Below we explain it and then show some examples of how to use it.

The denote-org-capture-with-prompts is like denote-org-capture but with optional prompt parameters.

When called without arguments, it does not prompt for anything. It just returns the front matter with title and keyword fields empty and the date and identifier fields specified. It also makes the file name consist of only the identifier plus the Org file name extension.

The file-naming scheme.

Otherwise, it produces a minibuffer prompt for every non-nil value that corresponds to the ‘TITLE’, ‘KEYWORDS’, ‘SUBDIRECTORY’, ‘DATE’, and ‘TEMPLATE’ arguments. The prompts are those used by the standard denote command and all of its utility commands.

Points of entry.

When returning the contents that fill in the Org capture template, the sequence is as follows: front matter, ‘TEMPLATE’, and then the value of the user option denote-org-capture-specifiers.

Important note: in the case of ‘SUBDIRECTORY’ actual subdirectories must exist—Denote does not create them. Same principle for ‘TEMPLATE’ as templates must exist and are specified in the user option denote-templates.

This is how one can incorporate denote-org-capture-with-prompts in their Org capture templates. Instead of passing a generic t which makes it hard to remember what the argument means, we use semantic keywords like ‘:title’ for our convenience (internally this does not matter as the value still counts as non-nil, so ‘:foo’ for ‘TITLE’ is treated the same as ‘:title’ or t).

;; This prompts for TITLE, KEYWORDS, and SUBDIRECTORY
(add-to-list 'org-capture-templates
             '("N" "New note with prompts (with denote.el)" plain
               (file denote-last-path)
               (function
                (lambda ()
                  (denote-org-capture-with-prompts :title :keywords :subdirectory)))
               :no-save t
               :immediate-finish nil
               :kill-buffer t
               :jump-to-captured t))

;; This prompts only for SUBDIRECTORY
(add-to-list 'org-capture-templates
             '("N" "New note with prompts (with denote.el)" plain
               (file denote-last-path)
               (function
                (lambda ()
                  (denote-org-capture-with-prompts nil nil :subdirectory)))
               :no-save t
               :immediate-finish nil
               :kill-buffer t
               :jump-to-captured t))

;; This prompts for TITLE and SUBDIRECTORY
(add-to-list 'org-capture-templates
             '("N" "New note with prompts (with denote.el)" plain
               (file denote-last-path)
               (function
                (lambda ()
                  (denote-org-capture-with-prompts :title nil :subdirectory)))
               :no-save t
               :immediate-finish nil
               :kill-buffer t
               :jump-to-captured t))

2.5 Create a note with the region’s contents

The command denote-region takes the contents of the active region and then calls the denote command. Once a new note is created, it inserts the contents of the region therein. This is useful to quickly elaborate on some snippet of text or capture it for future reference.

When the denote-region command is called with an active region, it finalises its work by calling denote-region-after-new-note-functions. This is an abnormal hook, meaning that the functions added to it are called with arguments. The arguments are two, representing the beginning and end positions of the newly inserted text.

A common use-case for Org mode users is to call the command org-insert-structure-template after a region is inserted. Emacs will thus prompt for a structure template, such as the one corresponding to a source block. In this case the function added to denote-region-after-new-note-functions does not actually need aforementioned arguments: it can simply declare those as ignored by prefixing the argument names with an underscore (an underscore is enough, but it is better to include a name for clarity). For example, the following will prompt for a structure template as soon as denote-region is done:

(defun my-denote-region-org-structure-template (_beg _end)
  (when (derived-mode-p 'org-mode)
    (activate-mark)
    (call-interactively 'org-insert-structure-template)))

(add-hook 'denote-region-after-new-note-functions #'my-denote-region-org-structure-template)

Remember that denote-region-after-new-note-functions are not called if denote-region is used without an active region.

• A custom denote-region that references the source

;; Variant of `my-denote-region' to reference the source

(defun my-denote-region-get-source-reference ()
  "Get a reference to the source for use with `my-denote-region'.
The reference is a URL or an Org-formatted link to a file."
  ;; We use a `cond' here because we can extend it to cover move
  ;; cases.
  (cond
   ((derived-mode-p 'eww-mode)
    (plist-get eww-data :url))
   ;; Here we are just assuming an Org format.  We can make this more
   ;; involved, if needed.
   (buffer-file-name
    (format "[[file:%s][%s]]" buffer-file-name (buffer-name)))))

(defun my-denote-region ()
  "Like `denote-region', but add the context afterwards.
For how the context is retrieved, see `my-denote-region-get-source-reference'."
  (interactive)
  (let ((context (my-denote-region-get-source-reference)))
    (call-interactively 'denote-region)
    (when context
      (goto-char (point-max))
      (insert "\n")
      (insert context))))

;; Add quotes around snippets of text captured with `denote-region' or `my-denote-region'.

(defun my-denote-region-org-structure-template (beg end)
  "Automatically quote (with Org syntax) the contents of `denote-region'."
  (when (derived-mode-p 'org-mode)
    (goto-char end)
    (insert "#+end_quote\n")
    (goto-char beg)
    (insert "#+begin_quote\n")))

(add-hook 'denote-region-after-new-note-functions #'my-denote-region-org-structure-template)

2.6 Open an existing note or create it if missing

Sometimes it is necessary to briefly interrupt the ongoing writing session to open an existing note or, if that is missing, to create it. This happens when a new tangential thought occurs and the user wants to confirm that an entry for it is in place. To this end, Denote provides the command denote-open-or-create as well as its more flexible counterpart denote-open-or-create-with-command.

The denote-open-or-create prompts to visit a file in the denote-directory. At this point, the user must type in search terms that match a file name. If the input does not return any matches and the user confirms their choice to proceed (usually by typing RET twice, depending on the minibuffer settings), denote-open-or-create will call the denote command interactively to create a new note. It will then use whatever prompts denote normally has, per the user option denote-prompts (Standard note creation). If the title prompt is involved (the default behaviour), the denote-open-or-create sets up this prompt to have the previous input as the default title of the note to-be-created. This means that the user can type RET at the empty prompt to re-use what they typed in previously. Commands to use previous inputs from the history are also available (‘M-p’ or ‘M-n’ in the minibuffer, which call previous-history-element and next-history-element by default). Accessing the history is helpful to, for example, make further edits to the available text.

The denote-open-or-create-with-command is like the above, except when it is about to create the new note it first prompts for the specific file-creating command to use (Points of entry). For example, the user may want to specify a signature for this new file, so they can select the denote-signature command.

Denote provides similar functionality for linking to an existing note or creating a new one (Link to a note or create it if missing).

2.7 Maintain separate directory silos for notes

The user option denote-directory accepts a value that represents the path to a directory, such as ‘~/Documents/notes’. Normally, the user will have one place where they store all their notes, in which case this arrangement shall suffice.

There is, however, the possibility to maintain separate directories of notes. By “separate”, we mean that they do not communicate with each other: no linking between them, no common keywords, nothing. Think of the scenario where one set of notes is for private use and another is for an employer. We call these separate directories “silos”.

To create silos, the user must specify a local variable at the root of the desired directory. This is done by creating a ‘.dir-locals.el’ file, with the following contents:

;;; Directory Local Variables.  For more information evaluate:
;;;
;;;     (info "(emacs) Directory Variables")

((nil . ((denote-directory . "/path/to/silo/"))))

When inside the directory that contains this ‘.dir-locals.el’ file, all Denote commands/functions for note creation, linking, the inference of available keywords, et cetera will use the silo as their point of reference (How to switch a silo). They will not read the global value of denote-directory. The global value of denote-directory is read everywhere else except the silos.

Use custom commands to select a silo.

In concrete terms, this is a representation of the directory structures (notice the ‘.dir-locals.el’ file is needed only for the silos):

;; This is the global value of 'denote-directory' (no need for a .dir-locals.el)
~/Documents/notes
|-- 20210303T120534--this-is-a-test__journal_philosophy.txt
|-- 20220303T120534--another-sample__journal_testing.md
`-- 20220620T181255--the-third-test__keyword.org

;; A silo with notes for the employer
~/different/path/to/notes-for-employer
|-- .dir-locals.el
|-- 20210303T120534--this-is-a-test__conference.txt
|-- 20220303T120534--another-sample__meeting.md
`-- 20220620T181255--the-third-test__keyword.org

;; Another silo with notes for my volunteering
~/different/path/to/notes-for-volunteering
|-- .dir-locals.el
|-- 20210303T120534--this-is-a-test__activism.txt
|-- 20220303T120534--another-sample__teambuilding.md
`-- 20220620T181255--the-third-test__keyword.org

It is possible to configure other user options of Denote to have a silo-specific value. For example, this one changes the denote-known-keywords only for this particular silo:

;;; Directory Local Variables.  For more information evaluate:
;;;
;;;     (info "(emacs) Directory Variables")

((nil . ((denote-directory . "/path/to/silo/")
         (denote-known-keywords . ("food" "drink")))))

This one is like the above, but also disables denote-infer-keywords:

;;; Directory Local Variables.  For more information evaluate:
;;;
;;;     (info "(emacs) Directory Variables")

((nil . ((denote-directory . "/path/to/silo/")
         (denote-known-keywords . ("food" "drink"))
         (denote-infer-keywords . nil))))

To expand the list of local variables to, say, cover specific major modes, we can do something like this:

;;; Directory Local Variables.  For more information evaluate:
;;;
;;;     (info "(emacs) Directory Variables")

((nil . ((denote-directory . "/path/to/silo/")
         (denote-known-keywords . ("food" "drink"))
         (denote-infer-keywords . nil)))
 (org-mode . ((org-hide-emphasis-markers . t)
              (org-hide-macro-markers . t)
              (org-hide-leading-stars . t))))

As not all user options have a “safe” local value, Emacs will ask the user to confirm their choice and to store it in the Custom code snippet that is normally appended to init file (or added to the file specified by the user option custom-file).

Finally, it is possible to have a ‘.dir-locals.el’ for subdirectories of any denote-directory. Perhaps to specify a different set of known keywords, while not making the subdirectory a silo in its own right. We shall not expand on such an example, as we trust the user to experiment with the best setup for their workflow.

Feel welcome to ask for help if the information provided herein is not sufficient. The manual shall be expanded accordingly.

• How to switch a silo
• Use custom commands to select a silo
• The ‘denote-silo-extras.el’
• Make Org export work with silos
• Make any Denote command work in a silo from anywhere

(defvar my-denote-silo-directories
  `("/home/prot/Videos/recordings"
    "/home/prot/Documents/books"
    ;; You don't actually need to include the `denote-directory' here
    ;; if you use the regular commands in their global context.  I am
    ;; including it for completeness.
    ,denote-directory)
  "List of file paths pointing to my Denote silos.
  This is a list of strings.")

(defvar my-denote-commands-for-silos
  '(denote
    denote-date
    denote-subdirectory
    denote-template
    denote-type)
  "List of Denote commands to call after selecting a silo.
  This is a list of symbols that specify the note-creating
  interactive functions that Denote provides.")

(defun my-denote-pick-silo-then-command (silo command)
  "Select SILO and run Denote COMMAND in it.
  SILO is a file path from `my-denote-silo-directories', while
  COMMAND is one among `my-denote-commands-for-silos'."
  (interactive
   (list (completing-read "Select a silo: " my-denote-silo-directories nil t)
         (intern (completing-read
                  "Run command in silo: "
                  my-denote-commands-for-silos nil t))))
  (let ((denote-directory silo))
    (call-interactively command)))

(require 'denote-silo-extras)

(setq org-export-allow-bind-keywords t)

(defun my-denote-journal-extras-new-or-existing-entry ()
  "Like `denote-journal-extras-new-or-existing-entry' for my silo."
  (interactive)
  (let ((denote-directory "/path/to/silo/"))
    (call-interactively 'denote-journal-extras-new-or-existing-entry)))

(define-key global-map (kbd "C-c n j") #'my-denote-journal-extras-new-or-existing-entry)

2.8 Exclude certain files from file prompts

The user option denote-excluded-files-regexp is a regular expression that matches files names which should be excluded from all Denote file prompts. Such prompts are present when linking to a file with one of the many commands, like denote-link (Linking notes), or when trying to open a file that may or may not exist (Open an existing note or create it if missing).

Functions that check for files include denote-directory-files and denote-file-prompt.

The match is performed with string-match-p.

For developers or advanced users.

2.9 Exclude certain directories from all operations

The user option denote-excluded-directories-regexp instructs all Denote functions that read or check file/directory names to omit directories that match the given regular expression. The regexp needs to match only the name of the directory, not its full path.

Affected operations include file prompts and functions that return the available files in the value of the user option denote-directory (Maintain separate directory silos for notes).

File prompts are used by several commands, such as denote-link and denote-subdirectory.

Functions that check for files include denote-directory-files and denote-directory-subdirectories.

The match is performed with string-match-p.

For developers or advanced users.

2.10 Exclude certain keywords from being inferred

The user option denote-excluded-keywords-regexp omits keywords that match a regular expression from the list of inferred keywords.

Keywords are inferred from file names and provided at relevant prompts as completion candidates when the user option denote-infer-keywords is non-nil.

The match is performed with string-match-p.

2.11 Use Denote commands from the menu bar or context menu

Denote registers a submenu for the menu-bar-mode. Users will find the entry called “Denote”. From there they can use their pointer to select a command. For a sample of how this looks, read the development log: https://protesilaos.com/codelog/2023-03-31-emacs-denote-menu/.

The command denote-menu-bar-mode toggles the presentation of the menu. It is enabled by default.

Emacs also provides support for operations through a context menu. This is typically the set of actions that are made available via a right mouse click. Users who enable context-menu-mode can register the Denote entry for it by adding the following to their configuration file:

(add-hook 'context-menu-functions #'denote-context-menu)

3.1 Rename a single file

The denote-rename-file command renames a file and updates existing front matter if appropriate. It is possible to do the same with multiple files (Rename multiple files interactively).

It always renames the file where it is located in the file system: it never moves it to another directory.

If in Dired, it considers ‘FILE’ to be the one at point, else it prompts with minibuffer completion for one. When called from Lisp, ‘FILE’ is a file system path represented as a string.

If ‘FILE’ has a Denote-compliant identifier, it retains it while updating components of the file name referenced by the user option denote-prompts (The denote-prompts option). By default, these are the ‘TITLE’ and ‘KEYWORDS’. The ‘SIGNATURE’ is another one. When called from Lisp, ‘TITLE’ and ‘SIGNATURE’ are strings, while ‘KEYWORDS’ is a list of strings.

If there is no identifier, denote-rename-file creates an identifier based on the following conditions:

1. If the denote-prompts includes an entry for date prompts, then it prompts for ‘DATE’ and takes its input to produce a new identifier. For use in Lisp, ‘DATE’ must conform with denote-valid-date-p.
2. If ‘DATE’ is nil (e.g. when denote-prompts does not include a date entry), it uses the file attributes to determine the last modified date of ‘FILE’ and formats it as an identifier.
3. As a fallback, it derives an identifier from the current date and time.
4. At any rate, if the resulting identifier is not unique among the files in the variable denote-directory, it increments it such that it becomes unique.

In interactive use, and assuming denote-prompts includes a title entry, the denote-rename-file makes the ‘TITLE’ prompt have prefilled text in the minibuffer that consists of the current title of ‘FILE’. The current title is either retrieved from the front matter (such as the ‘#+title’ in Org) or from the file name.

The command does the same for the ‘SIGNATURE’ prompt, subject to denote-prompts, by prefilling the minibuffer with the current signature of ‘FILE’, if any.

Same principle for the ‘KEYWORDS’ prompt: it converts the keywords in the file name into a comma-separated string and prefills the minibuffer with it (the ‘KEYWORDS’ prompt accepts more than one keywords, each separated by a comma, else the crm-separator).

For all prompts, the denote-rename-file interprets an empty input as an instruction to remove that file name component. For example, if a ‘TITLE’ prompt is available and ‘FILE’ is ‘20240211T093531--some-title__keyword1.org’ then it renames ‘FILE’ to ‘20240211T093531__keyword1.org’. If a file name component is present, but there is no entry for it in denote-prompts, keep it as-is.

[ NOTE: Please check with your minibuffer user interface how to provide an empty input. The Emacs default setup accepts the empty minibuffer contents as they are, though popular packages like vertico use the first available completion candidate instead. For vertico, the user must either move one up to select the prompt and then type ‘RET’ there with empty contents, or use the command vertico-exit-input with empty contents. That Vertico command is bound to ‘M-RET’ as of this writing on 2024-02-13 08:08 +0200. ]

When renaming ‘FILE’, the command reads its file type extension (like ‘.org’) and preserves it through the renaming process. Files that have no extension are left without one.

As a final step, ask for confirmation, showing the difference between old and new file names. Do not ask for confirmation if the user option denote-rename-confirmations does not contain the symbol modify-file-name (The denote-rename-confirmations option).

If ‘FILE’ has front matter for ‘TITLE’ and ‘KEYWORDS’, ask to rewrite their values in order to reflect the new input, unless denote-rename-confirmations lacks rewrite-front-matter. When the denote-save-buffers is nil (the default), do not save the underlying buffer, thus giving the user the option to double-check the result, such as by invoking the command diff-buffer-with-file. The rewrite of the ‘TITLE’ and ‘KEYWORDS’ in the front matter should not affect the rest of the front matter.

If the file does not have front matter but is among the supported file types (per denote-file-type), add front matter to the top of it and leave the buffer unsaved for further inspection (Front matter). Save the buffer if denote-save-buffers is non-nil (The denote-save-buffers option).

Construct the file name in accordance with the user option denote-file-name-components-order (Change the order of file name components).

Run the denote-after-rename-file-hook after renaming ‘FILE’.

This command is intended to (i) rename Denote files, (ii) convert existing supported file types to Denote notes, and (ii) rename non-note files (e.g. ‘PDF’) that can benefit from Denote’s file-naming scheme.

For a version of this command that works with multiple files one-by-one, use denote-dired-rename-files (Rename multiple files interactively).

• The denote-rename-confirmations option

3.2 Rename a single file based on its front matter

In the previous section, we covered the more general mechanism of the command denote-rename-file (Rename a single file). There is also a way to have the same outcome by making Denote read the data in the current file’s front matter and use it to construct/update the file name. The command for this is denote-rename-file-using-front-matter. It is only relevant for files that (i) are among the supported file types, per denote-file-type, and (ii) have the requisite front matter in place.

Suppose you have an ‘.org’ file with this front matter (Front matter):

#+title:      My sample note file
#+date:       [2022-08-05 Fri 13:10]
#+filetags:   :testing:
#+identifier: 20220805T131044

Its file name reflects this information:

20220805T131044--my-sample-note-file__testing.org

You want to change its title and keywords manually, so you modify it thus:

#+title:      My modified sample note file
#+date:       [2022-08-05 Fri 13:10]
#+filetags:   :testing:denote:emacs:
#+identifier: 20220805T131044

At this stage, the file name still shows the old title and keywords. You now invoke denote-rename-file-using-front-matter and it updates the file name to:

20220805T131044--my-modified-sample-note-file__testing_denote_emacs.org

By default, the renaming is subject to a “yes or no” prompt that shows the old and new names, just so the user is certain about the change. Though this can be modified (The denote-rename-confirmations option).

The identifier of the file, if any, is never modified even if it is edited in the front matter: Denote considers the file name to be the source of truth in this case, to avoid potential breakage with typos and the like.

This command constructs the file name in accordance with the user option denote-file-name-components-order (Change the order of file name components).

3.3 Rename multiple files interactively

The command denote-dired-rename-files (alias denote-dired-rename-marked-files) renames the files that are marked in a Dired buffer. Its behaviour is similar to the denote-rename-file in that it prompts for a title, keywords, and signature (Rename a single file). It does so over each marked file, renaming one after the other.

Unlike denote-rename-file, the command denote-dired-rename-files does not ask to confirm the changes made to the files: it performs them outright (same as setting denote-rename-confirmations to a nil value). This is done to make it easier to rename multiple files without having to confirm each step. For an even more direct approach, check the command denote-dired-rename-marked-files-with-keywords.

• Rename by writing only keywords
• Rename multiple files based on their front matter

3.4 Rename multiple files at once by asking only for keywords

The denote-dired-rename-marked-files-with-keywords command renames marked files in Dired to conform with our file-naming scheme. It does so by writing keywords to them. Specifically, it does the following:

• retains the file’s existing name and makes it the ‘TITLE’ field, per Denote’s file-naming scheme;
• sluggifies the ‘TITLE’ and adjusts its letter casing, according to our conventions;
• prepends an identifier to the ‘TITLE’, if one is missing;
• preserves the file’s extension, if any;
• prompts once for ‘KEYWORDS’ and applies the user’s input to the corresponding field in the file name, rewriting any keywords that may exist while removing keywords that do exist if ‘KEYWORDS’ is empty;
• adds or rewrites existing front matter to the underlying file, if it is recognized as a Denote note (per the denote-file-type user option), such that it includes the new keywords.

[ Note that the affected buffers are not saved, unless the user option denote-rename-no-confirm is non-nil. Users can thus check them to confirm that the new front matter does not cause any problems (e.g. with the diff-buffer-with-file command). Multiple buffers can be saved in one go with the command save-some-buffers (read its doc string). ]

Construct the file name in accordance with the user option denote-file-name-components-order (Change the order of file name components).

Run the denote-after-rename-file-hook after the renaming is done.

For more specialized versions of this command that only add or remove keywords, use denote-dired-rename-marked-files-add-keywords and denote-dired-rename-marked-files-remove-keywords, respectively.

3.5 Rename multiple files based on their front matter

As already noted, Denote can rename a file based on the data in its front matter (Rename a single file based on its front matter). The command denote-dired-rename-marked-files-using-front-matter extends this principle to a batch operation which applies to all marked files in Dired.

Marked files must count as notes for the purposes of Denote, which means that they at least have an identifier in their file name and use a supported file type, per denote-file-type. Files that do not meet this criterion are ignored, because Denote cannot know if they have front matter and what that may be. For such files, it is still possible to rename them interactively (Rename multiple files interactively).

3.6 Rename a file by changing only its file type

The command denote-change-file-type-and-front-matter provides the convenience of converting a note taken in one file type, say, ‘.txt’ into another like ‘.org’. It presents a choice among the denote-file-type options.

The conversion does NOT modify the existing front matter. Instead, it prepends new front matter to the top of the file. We do this as a safety precaution since the user can, in principle, add arbitrary extras to their front matter that we would not want to touch.

If in Dired, denote-change-file-type-and-front-matter operates on the file at point, else the current file, else it prompts with minibuffer completion for one.

The title of the file is retrieved from a line starting with a title field in the file’s front matter, depending on the previous file type (e.g. ‘#+title’ for Org). The same process applies for keywords.

As a final step, the command asks for confirmation, showing the difference between old and new file names.

This command constructs the file name in accordance with the user option denote-file-name-components-order (Change the order of file name components).

3.7 Rename a file by adding or removing a title interactively

The command denote-rename-file-title streamlines the process of interactively adding or removing a title to/from a file, while changing its file name accordingly. It asks for a title using the familiar minibuffer prompt (Standard note creation). It then renames the file. The command respect the values of denote-rename-confirmations and denote-save-buffers:

• The denote-rename-confirmations option.
• The denote-save-buffers option.

Technically, denote-rename-file-title is a wrapper for denote-rename-file, doing all the things that does (Rename a single file).

Concretely, this command can add or remove a title in one go. It does it by prepopulating the minibuffer prompt with the existing title. Users can then modify it. An empty input means to remove the title altogether (The file-naming scheme).

[ NOTE: Please check with your minibuffer user interface how to provide an empty input. The Emacs default setup accepts the empty minibuffer contents as they are, though popular packages like vertico use the first available completion candidate instead. For vertico, the user must either move one up to select the prompt and then type ‘RET’ there with empty contents, or use the command vertico-exit-input with empty contents. That Vertico command is bound to ‘M-RET’ as of this writing on 2024-06-30 10:37 +0300. ]

3.8 Rename a file by adding or removing keywords interactively

The command denote-rename-file-keywords streamlines the process of interactively adding or removing keywords to a file, while changing its file name and front matter accordingly. It asks for keywords using the familiar minibuffer prompt (Standard note creation). It then renames the file (Rename a single file based on its front matter). The command respect the values of denote-rename-confirmations and denote-save-buffers:

• The denote-rename-confirmations option.
• The denote-save-buffers option.

Technically, denote-rename-file-keywords is a wrapper for denote-rename-file, doing all the things that does (Rename a single file).

Concretely, this command can add or remove keywords in one go. It does it by prepopulating the minibuffer prompt with the existing keywords. Users can then use the crm-separator (normally a comma), to write new keywords or edit what is in the prompt to rewrite them accordingly. An empty input means to remove all keywords (The file-naming scheme).

[ NOTE: Please check with your minibuffer user interface how to provide an empty input. The Emacs default setup accepts the empty minibuffer contents as they are, though popular packages like vertico use the first available completion candidate instead. For vertico, the user must either move one up to select the prompt and then type ‘RET’ there with empty contents, or use the command vertico-exit-input with empty contents. That Vertico command is bound to ‘M-RET’ as of this writing on 2024-06-30 10:37 +0300. ]

3.9 Rename a file by adding or removing a signature interactively

The command denote-rename-file-signature streamlines the process of interactively adding or removing a signature to/from a file, while changing its file name accordingly. It asks for a signature using the familiar minibuffer prompt (Standard note creation). It then renames the file. The command respect the values of denote-rename-confirmations and denote-save-buffers:

• The denote-rename-confirmations option.
• The denote-save-buffers option.

Technically, denote-rename-file-signature is a wrapper for denote-rename-file, doing all the things that does (Rename a single file).

Concretely, this command can add or remove a signature in one go. It does it by prepopulating the minibuffer prompt with the existing signature. Users can then modify it. An empty input means to remove the signature altogether (The file-naming scheme).

[ NOTE: Please check with your minibuffer user interface how to provide an empty input. The Emacs default setup accepts the empty minibuffer contents as they are, though popular packages like vertico use the first available completion candidate instead. For vertico, the user must either move one up to select the prompt and then type ‘RET’ there with empty contents, or use the command vertico-exit-input with empty contents. That Vertico command is bound to ‘M-RET’ as of this writing on 2024-06-30 10:37 +0300. ]

3.10 Find duplicate identifiers and put them in a Dired buffer

Denote takes care to create unique identifiers, though its mechanism relies on reading the existing identifiers in the denote-directory or the current directory. When we are renaming files across different directories, there is a small chance that some files have the same attributes and are thus assigned identical identifiers. If those files ever make it into a consolidated denote-directory, we will have duplicates, which break the linking mechanism.

As this is an edge case, we do not include any code to address it in the Denote code base. Though here is a way to find duplicate identifiers inside the current directory:

(defun my-denote--get-files-in-dir (directory)
  "Return file names in DIRECTORY."
  (directory-files directory :full-paths directory-files-no-dot-files-regexp))

(defun my-denote--same-identifier-p (file1 file2)
  "Return non-nil if FILE1 and FILE2 have the same identifier."
  (let ((id1 (denote-retrieve-filename-identifier file1))
        (id2 (denote-retrieve-filename-identifier file2)))
    (equal id1 id2)))

(defun my-denote-find-duplicate-identifiers (directory)
  "Find all files in DIRECTORY that need a new identifier."
  (let* ((ids (my-denote--get-files-in-dir directory))
         (unique-ids (seq-uniq ids #'my-denote--same-identifier-p)))
    (seq-difference ids unique-ids #'equal)))

(defun my-denote-dired-show-duplicate-identifiers (directory)
  "Put duplicate identifiers from DIRECTORY in a dedicated Dired buffer."
  (interactive
   (list
    (read-directory-name "Select DIRECTORY to check for duplicate identifiers: " default-directory)))
  (if-let ((duplicates (my-denote-find-duplicate-identifiers directory)))
      (dired (cons (format "Denote duplicate identifiers" directory) duplicates))
    (message "No duplicates identifiers in `%s'" directory)))

Evaluate this code and then call the command my-denote-dired-show-duplicate-identifiers. If there are duplicates, it will put them in a dedicated Dired buffer. From there, you can view the file contents as usual, and manually edit the identifiers as you see fit (e.g. edit them one by one, or change to the writable Dired and record a keyboard macro that makes use of a counter to increment by 1—contact me if you need any help).

3.11 Faces used by rename commands

These are the faces used by the various Denote rename commands to style or highlight the old/new/current file shown in the relevant minibuffer prompts:

• denote-faces-prompt-current-name
• denote-faces-prompt-new-name
• denote-faces-prompt-old-name

4.1 Change the order of file name components

Our standard file-naming scheme prescribes a specific order for the file name components (The file-naming scheme). Though we provide the user option denote-file-name-components-order to let the user reorder them as they see fit.

The value of this user option is a list of the following symbols:

• identifier: This is the combination of the date and time. When it is the first on the list, it looks like ‘20240519T073456’ and does not have a component separator of its own due its unambiguous format. When it is placed anywhere else in the file name, it is prefixed with ‘@@’, so it looks like ‘@@20240519T073456’.
• signature: This is an arbitrary string that can be used to qualify the file in some way, according to the user’s methodology (e.g. to add a sequence to notes). The string is always prefixed with the == to remain unambiguous.
• title: This is an arbitrary string which describes the file. It is always prefixed with ‘--’ to be unambiguous.
• keywords: This is a series of one or more words that succinctly group the file. Multiple keywords are separated by an underscore prefixed to each of them. The file name component is always prefixed with ‘__’.

All four symbols must appear exactly once. Duplicates are ignored. Any missing symbol is added automatically.

Some examples:

(setq denote-file-name-components-order '(identifier signature title keywords))
;; => 20240519T07345==hello--this-is-the-title__denote_testing.org

(setq denote-file-name-components-order '(signature identifier title keywords))
;; => ==hello@@20240519T07345--this-is-the-title__denote_testing.org

(setq denote-file-name-components-order '(title signature identifier keywords))
;; => --this-is-the-title==hello@@20240519T07345__denote_testing.org

(setq denote-file-name-components-order '(keywords title signature identifier))
;; => __denote_testing--this-is-the-title==hello@@20240519T07345.org

Also see how to configure the Denote prompts, which affect which components are actually used in the order specified herein (The denote-prompts option).

Before deciding on this, please consider the longer-term implications of file names with varying patterns. Consistency makes things predictable and thus easier to find. So pick one order and never touch it again. When in doubt, leave the default file-naming scheme as-is.

4.2 Sluggification of file name components

Files names can contain any character that the file system permits. Denote imposes a few additional restrictions:

• The tokens “‘=", =__’ and ‘--’ are interpreted by Denote and should appear only once.
• The dot character is not allowed in a note’s file name, except to indicate the file type extension. Denote recognises two extensions for encrypted files, like ‘.txt.gpg’.

By default, Denote enforces other rules to file names through the user option denote-file-name-slug-functions. These rules are applied to file names by default:

• What we count as “illegal characters” are removed. The constant denote-excluded-punctuation-regexp holds the relevant value.
• Input for a file title is hyphenated. The original value is preserved in the note’s contents (Front matter).
• Spaces or other delimiters are removed from keywords, meaning that ‘hello-world’ becomes ‘helloworld’. This is because hyphens in keywords do not work everywhere, such as in Org. Plus, hyphens are word separators in the title and we want to keep distinct separators for each component to make search easier and semantic (Features of the file-naming scheme for searching or filtering).
• Signatures are like the above, but use the equals sign instead of hyphens as a word separator.
• All file name components are downcased. Further down we document how to deviate from these rules, such as to accept input of the form ‘helloWorld’ or ‘HelloWorld’ verbatim.

Denote imposes these restrictions to enforce uniformity, which is helpful long-term as it keeps all files with the same predictable pattern. Too many permutations make searches more difficult to express accurately and be confident that the matches cover all files. Nevertheless, one of the principles of Denote is its flexibility or hackability and so users can deviate from the aforementioned (User-defined sluggification of file name components).

4.3 User-defined sluggification of file name components

The user option denote-file-name-slug-functions controls the sluggification of file name components (Sluggification of file name components). The default method is outlined above and in the previous section (The file-naming scheme).

The value of this user option is an alist where each element is a cons cell of the form ‘(COMPONENT . METHOD)’. For example, here is the default value:

'((title . denote-sluggify-title)
  (signature . denote-sluggify-signature)
  (keyword . denote-sluggify-keyword))

• The ‘COMPONENT’ is an unquoted symbol among ‘title’, ‘signature’, ‘keyword’, which refers to the corresponding component of the file name.
• The ‘METHOD’ is a function to format the given component. This function must take a string as its parameter and return the string formatted for the file name. Note that even in the case of the ‘keyword’ component, the function receives one string representing a single keyword and returns it formatted for the file name. Joining the keywords together is handled internally by Denote.

One commonly requested deviation from the sluggification rules is to not sluggify individual keywords, such that the user’s input is taken as-is. This can be done as follows:

(setq denote-file-name-slug-functions
      '((title . denote-sluggify-title)
        (keyword . identity)
        (signature . denote-sluggify-signature)))

The identity function simply returns the string it receives, thus not altering it in any way.

Another approach is to keep the sluggification but not downcase the string. We can do this by modifying the original functions used by Denote. For example, we have this:

;; The original function for reference
(defun denote-sluggify-title (str)
  "Make STR an appropriate slug for title."
  (downcase (denote--slug-hyphenate (denote--slug-no-punct str))))

;; Our variant of the above, which does the same thing except from
;; downcasing the string.
(defun my-denote-sluggify-title (str)
  "Make STR an appropriate slug for title."
  (denote--slug-hyphenate (denote--slug-no-punct str)))

;; Now we use our function to sluggify titles without affecting their
;; letter casing.
(setq denote-file-name-slug-functions
      '((title . my-denote-sluggify-title) ; our function here
        (signature . denote-sluggify-signature)
        (keyword . denote-sluggify-keyword)))

Follow this principle for all the sluggification functions (Custom sluggification to remove non-ASCII characters).

To access the source code, use either of the following built-in methods:

1. Call the command find-library and search for denote. Then navigate to the symbol you are searching for.
2. Invoke the command describe-symbol, search for the symbol you are interested in, and from the resulting Help buffer either click on the first link or do ‘M-x help-view-source’ (bound to ‘s’ in Help buffers, by default).

Remember that deviating from the default file-naming scheme of Denote will make things harder to use in the future, as files can/will have permutations that create uncertainty. The sluggification scheme and concomitant restrictions we impose by default are there for a very good reason: they are the distillation of years of experience. Here we give you what you wish, but bear in mind it may not be what you need. You have been warned.

• Custom sluggification to remove non-ASCII characters

;; These are the same as the default Denote sluggification functions,
;; except they remove all non-ASCII characters.
(defun my-denote-sluggify-title (str)
  (downcase
   (denote--slug-hyphenate
    (denote--slug-no-punct
     (denote-slug-keep-only-ascii str)))))

(defun my-denote-sluggify-signature (str)
  (downcase
   (denote--slug-put-equals
    (denote--slug-no-punct-for-signature
     (denote-slug-keep-only-ascii str)
     "-+"))))

(defun my-denote-sluggify-keyword (str)
  (downcase
   (replace-regexp-in-string
    "-" ""
    (denote--slug-hyphenate
     (denote--slug-no-punct
      (denote-slug-keep-only-ascii str))))))

(defcustom denote-file-name-slug-functions
  '((title . my-denote-sluggify-title)
    (signature . my-denote-sluggify-signature)
    (keyword . my-denote-sluggify-keyword)))

4.4 Features of the file-naming scheme for searching or filtering

By default, file names have three fields and two sets of field delimiters between them:

DATE--TITLE__KEYWORDS.EXTENSION

When a signature is present, this becomes:

DATE==SIGNATURE--TITLE__KEYWORDS.EXTENSION

Field delimiters practically serve as anchors for easier searching. Consider this example:

20220621T062327==1a2--introduction-to-denote__denote_emacs.txt

You will notice that there are two matches for the word ‘denote’: one in the title field and another in the keywords’ field. Because of the distinct field delimiters, if we search for ‘-denote’ we only match the first instance while ‘_denote’ targets the second one. When sorting through your notes, this kind of specificity is invaluable—and you get it for free from the file names alone! Similarly, a search for ‘=1’ will show all notes that are related to each other by virtue of their signature.

Users can get a lot of value out of this simple yet effective arrangement, even if they have no knowledge of regular expressions. One thing to consider, for maximum effect, is to avoid using multi-word keywords as those can get hyphenated like the title and will thus interfere with the above: either set the user option denote-allow-multi-word-keywords to nil or simply insert single words at the relevant prompts.

5.1 Change the front matter format

Per Denote’s design principles, the code is hackable. All front matter is stored in variables that are intended for public use. We do not declare those as “user options” because (i) they expect the user to have some degree of knowledge in Emacs Lisp and (ii) implement custom code.

[ NOTE for tinkerers: code intended for internal use includes double hyphens in its symbol. “Internal use” means that it can be changed without warning and with no further reference in the change log. Do not use any of it without understanding the consequences. ]

The variables which hold the front matter format are:

• denote-org-front-matter

• denote-text-front-matter

• denote-toml-front-matter

• denote-yaml-front-matter

These variables have a string value with specifiers that are used by the format function. The formatting operation passes four arguments which include the values of the given entries. If you are an advanced user who wants to edit this variable to affect how front matter is produced, consider using something like ‘%2$s’ to control where the Nth argument is placed.

When editing the value, make sure to:

1. Not use empty lines inside the front matter block.
2. Insert at least one empty line after the front matter block and do not use any empty line before it.

These help with consistency and might prove useful if we ever need to operate on the front matter as a whole.

With those granted, below are some examples. The approach is the same for all variables.

;; Like the default, but upcase the entries
(setq denote-org-front-matter
  "#+TITLE:      %s
#+DATE:       %s
#+FILETAGS:   %s
#+IDENTIFIER: %s
\n")

;; Change the order (notice the %N$s notation)
(setq denote-org-front-matter
  "#+title:      %1$s
#+filetags:   %3$s
#+date:       %2$s
#+identifier: %4$s
\n")

;; Remove the date
(setq denote-org-front-matter
  "#+title:      %1$s
#+filetags:   %3$s
#+identifier: %4$s
\n")

;; Remove the date and the identifier
(setq denote-org-front-matter
  "#+title:      %1$s
#+filetags:   %3$s
\n")

Note that setq has a global effect: it affects the creation of all new notes. Depending on the workflow, it may be preferrable to have a custom command which let binds the different format. We shall not provide examples at this point as this is a more advanced feature and we are not yet sure what the user’s needs are. Please provide feedback and we shall act accordingly.

5.2 Regenerate front matter

Sometimes the user needs to produce new front matter for an existing note. Perhaps because they accidentally deleted a line and could not undo the operation. The command denote-add-front-matter can be used for this very purpose.

In interactive use, denote-add-front-matter must be invoked from a buffer that visits a Denote note. It prompts for a title and then for keywords. These are the standard prompts we already use for note creation, so the keywords’ prompt allows minibuffer completion and the input of multiple entries, each separated by a comma (Points of entry).

The newly created front matter is added to the top of the file.

This command does not rename the file (e.g. to update the keywords). To rename a file by reading its front matter as input, the user can rely on denote-rename-file-using-front-matter (Renaming files).

Note that denote-add-front-matter is useful only for existing Denote notes. If the user needs to convert a generic text file to a Denote note, they can use one of the command which first rename the file to make it comply with our file-naming scheme and then add the relevant front matter.

6.1 Adding a single link

The denote-link command inserts a link at point to a file specified at the minibuffer prompt. Links are formatted depending on the file type of the current note. In Org and plain text buffers, links are formatted thus: ‘[[denote:IDENTIFIER][DESCRIPTION]]’. While in Markdown they are expressed as ‘[DESCRIPTION](denote:IDENTIFIER)’.

[ We optionally support links to Org headings (The denote-org-store-link-to-heading user option). Other file types do not have the features of Org, so we cannot generalise this. ]

When denote-link is called with a prefix argument (‘C-u’ by default), it formats links like ‘[[denote:IDENTIFIER]]’, regardless of file type (Fontify links in non-Org buffers). The user might prefer its simplicity.

By default, the description of the link is determined thus:

• If the region is active, its text becomes the description of the link. In other words, the region text becomes the link.
• If the region is active but has no text, the description is empty and so the link is formatted the same way as if using the ‘C-u’ prefix argument.
• If there is no region active, the description consists of the target file’s signature and title (Insert link to file with signature). The title is retrieved either from the front matter or the file name.
• If the target file has no signature, the title is used.

Links are created only for files which qualify as a “note” for our purposes (Linking notes). Users who need to link to Denote files from anywhere, can write a simple command to that effect:

(defun my-denote-link-global (file file-type description &optional id-only)
  "Like the `denote-link', but works in any buffer.
The FILE, FILE-TYPE, DESCRIPTION, and ID-ONLY have the same meaning as
in `denote-link'."
  (interactive
   (let* ((file (denote-file-prompt nil "Link to FILE"))
          (file-type (denote-filetype-heuristics buffer-file-name))
          (description (when (file-exists-p file)
                         (denote--link-get-description file))))
     (list file file-type description current-prefix-arg)))
  (unless (file-exists-p file)
    (user-error "The linked file does not exists"))
  (let ((beg (point)))
    (denote--delete-active-region-content)
    (insert (denote-format-link file description file-type id-only))
    (unless (derived-mode-p 'org-mode)
      (make-button beg (point) 'type 'denote-link-button))))

Links are styled with the denote-faces-link face, which looks exactly like an ordinary link by default. This is just a convenience for the user/theme in case they want ‘denote:’ links to remain distinct from other links.

6.2 The denote-org-store-link-to-heading user option

The user option denote-org-store-link-to-heading determines whether org-store-link links to the current Org heading (such links are merely “stored” and need to be inserted afterwards with the command org-insert-link). Note that the org-capture command uses the org-link internally if it has to store a link.

When its value is non-nil, org-store-link stores a link to the current Org heading inside the Denote Org file. If the heading does not have a ‘CUSTOM_ID’, it creates it and includes it in the heading’s ‘PROPERTIES’ drawer. If a ‘CUSTOM_ID’ exists, org-store-link use it as-is.

This makes the resulting link a combination of the ‘denote:’ link type, pointing to the identifier of the current file, plus the value of the heading’s ‘CUSTOM_ID’, such as:

• ‘[[denote:20240118T060608][Some test]]’
• ‘[[denote:20240118T060608::#h:eed0fb8e-4cc7-478f-acb6-f0aa1a8bffcd][Some test::Heading text]]’

Both lead to the same Denote file, but the latter jumps to the heading with the given ‘CUSTOM_ID’. Notice that the link to the heading also has a different description, which includes the heading text.

The value of the ‘CUSTOM_ID’ is determined by the Org user option org-id-method. The sample shown above uses the default UUID infrastructure.

If denote-org-store-link-to-heading is set to a nil value, the command org-store-link only stores links to the Denote file (using its identifier), but not to the given heading. This is what Denote was doing in versions prior to ‘2.3.0’.

Note that the optional extension ‘denote-org-extras.el’ defines the command denote-org-extras-link-to-heading, which always links to a file+heading regardless of the aforementioned user option (Insert link to an Org file with a further pointer to a heading).

[ This feature only works in Org mode files, as other file types do not have a linking mechanism that handles unique identifiers for headings or other patterns to jump to. If org-store-link is invoked in one such file, it captures only the Denote identifier of the file, even if this user option is set to a non-nil value. ]

6.3 Insert link to an Org file with a further pointer to a heading

As part of the optional ‘denote-org-extras.el’ extension, the command denote-org-extras-link-to-heading prompts for a link to an Org file and then asks for a heading therein, using minibuffer completion. Once the user provides input at the two prompts, the command inserts a link at point which has the following pattern: ‘[[denote:IDENTIFIER::#ORG-HEADING-CUSTOM-ID]][Description::Heading text]]’.

Because only Org files can have links to individual headings, the command denote-org-extras-link-to-heading prompts only for Org files (i.e. files which include the ‘.org’ extension). Remember that Denote works with many file types (The file-naming scheme).

This feature is similar to the concept of the user option denote-org-store-link-to-heading (The denote-org-store-link-to-heading user option). It is, however, interactive and differs in the directionality of the action. With that user option, the command org-store-link will generate a ‘CUSTOM_ID’ for the current heading (or capture the value of one as-is), giving the user the option to then call org-insert-link wherever they see fit. By contrast, the command denote-org-extras-link-to-heading prompts for a file, then a heading, and inserts the link at point.

Just as with files, it is possible to show backlinks for the given heading (Backlinks for Org headings).

6.4 Insert links matching a regexp

The command denote-add-links adds links at point matching a regular expression or plain string. The links are inserted as a typographic list, such as:

- link1
- link2
- link3

Each link is formatted according to the file type of the current note, as explained further above about the denote-link command. The current note is excluded from the matching entries (adding a link to itself is pointless).

When called with a prefix argument (‘C-u’) denote-add-links will format all links as ‘[[denote:IDENTIFIER]]’, hence a typographic list:

- [[denote:IDENTIFIER-1]]
- [[denote:IDENTIFIER-2]]
- [[denote:IDENTIFIER-3]]

Same examples of a regular expression that can be used with this command:

• ‘journal’ match all files which include ‘journal’ anywhere in their name.
• ‘_journal’ match all files which include ‘journal’ as a keyword.
• ‘^2022.*_journal’ match all file names starting with ‘2022’ and including the keyword ‘journal’.
• ‘\.txt’ match all files including ‘.txt’. In practical terms, this only applies to the file extension, as Denote automatically removes dots (and other characters) from the base file name.

If files are created with denote-sort-keywords as non-nil (the default), then it is easy to write a regexp that includes multiple keywords in alphabetic order:

• ‘_denote.*_package’ match all files that include both the ‘denote’ and ‘package’ keywords, in this order.
• ‘\(.*denote.*package.*\)\|\(.*package.*denote.*\)’ is the same as above, but out-of-order.

Remember that regexp constructs only need to be escaped once (like ‘\|’) when done interactively but twice when called from Lisp. What we show above is for interactive usage.

Links are created only for files which qualify as a “note” for our purposes (Linking notes).

6.5 Insert link to file with signature

The command denote-link-with-signature prompts for a file among those that contain a ‘==SIGNATURE’ and inserts a link to it. The description of the link includes the text of the signature and that of the file’s title, if any. For example, a link to the following file:

20230925T144303==abc--my-first-signature-note__denote_testing.txt

will get this link: ‘[[denote:20230925T144303][abc My first signature note]]’.

For more advanced uses, refer to the doc string of the denote-link function (Adding a single link).

6.6 Insert links from marked files in Dired

The command denote-link-dired-marked-notes is similar to denote-add-links in that it inserts in the buffer a typographic list of links to Denote notes (Insert links matching a regexp). Though instead of reading a regular expression, it lets the user mark files in Dired and link to them. This should be easier for users of all skill levels, instead of having to write a potentially complex regular expression.

If there are multiple buffers that visit a Denote note, this command will ask to select one among them, using minibuffer completion. If there is only one buffer, it will operate in it outright. If there are no buffers, it will produce an error.

With optional ‘ID-ONLY’ as a prefix argument (‘C-u’ by default), the command inserts links with just the identifier, which is the same principle as with denote-link and others (Adding a single link).

The command denote-link-dired-marked-notes is meant to be used from a Dired buffer.

As always, links are created only for files which qualify as a “note” for our purposes (Linking notes).

6.7 Link to an existing note or create a new one

In one’s note-taking workflow, there may come a point where they are expounding on a certain topic but have an idea about another subject they would like to link to (Linking notes). The user can always rely on the other linking facilities we have covered herein to target files that already exist. Though they may not know whether they already have notes covering the subject or whether they would need to write new ones. To this end, Denote provides two convenience commands:

denote-link-after-creating

Create new note in the background and link to it directly.

Use denote interactively to produce the new note. Its doc string or this manual explains which prompts will be used and under what conditions (Standard note creation).

With optional ‘ID-ONLY’ as a prefix argument (this is the ‘C-u’ key, by default) create a link that consists of just the identifier. Else try to also include the file’s title. This has the same meaning as in denote-link (Adding a single link).

IMPORTANT NOTE: Normally, denote does not save the buffer it produces for the new note (The denote-save-buffer-after-creation option). This is a safety precaution to not write to disk unless the user wants it (e.g. the user may choose to kill the buffer, thus cancelling the creation of the note). However, for this command the creation of the note happens in the background and the user may miss the step of saving their buffer. We thus have to save the buffer in order to (i) establish valid links, and (ii) retrieve whatever front matter from the target file.

denote-link-after-creating-with-command

This command is like denote-link-after-creating except it prompts for a note-creating command (Points of entry). Use this to, for example, call denote-signature so that the newly created note has a signature as part of its file name. Optional ‘ID-ONLY’ has the same meaning as in the command denote-link-after-creating.

denote-link-or-create

Use denote-link on ‘TARGET’ file, creating it if necessary.

If ‘TARGET’ file does not exist, call denote-link-after-creating which runs the denote command interactively to create the file. The established link will then be targeting that new file.

If ‘TARGET’ file does not exist, add the user input that was used to search for it to the history of the denote-file-prompt. The user can then retrieve and possibly further edit their last input, using it as the newly created note’s actual title. At the denote-file-prompt type ‘M-p’ with the default key bindings, which calls previous-history-element.

With optional ‘ID-ONLY’ as a prefix argument create a link with just the file’s identifier. This has the same meaning as in denote-link.

This command has the alias denote-link-to-existing-or-new-note, which helps with discoverability.

denote-link-or-create-with-command

This is like the above, except when it is about to create the new note it first prompts for the specific file-creating command to use (Points of entry). For example, the user may want to specify a signature for this new file, so they can select the denote-signature command.

In all of the above, an optional prefix argument (‘C-u’ by default) creates a link that consists of just the identifier. This has the same meaning as in the regular denote-link command.

Denote provides similar functionality for opening an existing note or creating a new one (Open an existing note or create it if missing).

6.8 The backlinks’ buffer

The command denote-backlinks produces a bespoke buffer which displays backlinks to the current note. A “backlink” is a link back to the present entry.

By default, the backlinks’ buffer is designed to display the file name of the note linking to the current entry. Each file name is presented on its own line, like this:

Backlinks to "On being honest" (20220614T130812)
------------------------------------------------

20220614T145606--let-this-glance-become-a-stare__journal.txt
20220616T182958--feeling-butterflies-in-your-stomach__journal.txt

When the user option denote-backlinks-show-context is non-nil, the backlinks’ buffer displays the line on which a link to the current note occurs. It also shows multiple occurrences, if present. It looks like this (and has the appropriate fontification):

Backlinks to "On being honest" (20220614T130812)
------------------------------------------------

20220614T145606--let-this-glance-become-a-stare__journal.txt
37: growing into it: [[denote:20220614T130812][On being honest]].
64: As I said in [[denote:20220614T130812][On being honest]] I have never
20220616T182958--feeling-butterflies-in-your-stomach__journal.txt
62: indifference.  In [[denote:20220614T130812][On being honest]] I alluded

The command denote-backlinks-toggle-context will toggle between the compact and detailed views inside of the current backlinks buffer.

Note that the width of the lines in the context depends on the underlying file. In the above example, the lines are split at the fill-column. Long lines will show up just fine. Also note that the built-in user option xref-truncation-width can truncate long lines to a given maximum number of characters.

Speed up backlinks’ buffer creation?

The backlinks’ buffer runs the major-mode denote-backlinks-mode. It binds keys to move between links with ‘n’ (next) and ‘p’ (previous). These are stored in the denote-backlinks-mode-map (use ‘M-x describe-mode’ (‘C-h m’) in an unfamiliar buffer to learn more about it). When the user option denote-backlinks-show-context is non-nil, all relevant Xref key bindings are fully functional: again, check describe-mode.

The backlinking facility uses Emacs’ built-in Xref infrastructure. On some operating systems, the user may need to add certain executables to the relevant environment variable.

Why do I get “Search failed with status 1” when I search for backlinks?

Backlinks to the current file can also be visited by using the minibuffer completion interface with the denote-find-backlink command (Visiting linked files via the minibuffer).

The placement of the backlinks’ buffer is subject to the user option denote-backlinks-display-buffer-action. Due to the nature of the underlying display-buffer mechanism, this inevitably is a relatively advanced feature. By default, the backlinks’ buffer is displayed below the current window. The doc string of our user option includes a sample configuration that places the buffer in a left side window instead. Reproducing it here for the sake of convenience:

(setq denote-backlinks-display-buffer-action
      '((display-buffer-reuse-window
         display-buffer-in-side-window)
        (side . left)
        (slot . 99)
        (window-width . 0.3)
        (dedicated . t)
        (preserve-size . (t . t))))

• Backlinks for Org headings

6.9 Writing metanotes

A “metanote” is an entry that describes other entries who have something in common. Writing metanotes can be part of a workflow where the user periodically reviews their work in search of patterns and deeper insights. For example, you might want to read your journal entries from the past year to reflect on your experiences, evolution as a person, and the like.

The commands denote-add-links, denote-link-dired-marked-notes are suited for this task.

Insert links matching a regexp.

Insert links from marked files in Dired.

You will create your metanote the way you use Denote ordinarily (metanotes may have the ‘metanote’ keyword, among others), write an introduction or however you want to go about it, invoke the command which inserts multiple links at once (see the above-cited nodes), and continue writing.

Metanotes can serve as entry points to groupings of individual notes. They are not the same as a filtered list of files, i.e. what you would do in Dired or the minibuffer where you narrow the list of notes to a given query. Metanotes contain the filtered list plus your thoughts about it. The act of purposefully grouping notes together and contemplating on their shared patterns is what adds value.

Your future self will appreciate metanotes for the function they serve in encapsulating knowledge, while current you will be equipped with the knowledge derived from the deliberate self-reflection.

6.10 Visiting linked files via the minibuffer

Denote has a major-mode-agnostic mechanism to collect all linked file references in the current buffer and return them as an appropriately formatted list. This list can then be used in interactive commands. The denote-find-link is such a command. It uses minibuffer completion to visit a file that is linked to from the current note. The candidates have the correct metadata, which is ideal for integration with other standards-compliant tools (Extending Denote). For instance, a package such as ‘marginalia’ will display accurate annotations, while the ‘embark’ package will be able to work its magic such as in exporting the list into a filtered Dired buffer (i.e. a familiar Dired listing with only the files of the current minibuffer session).

To visit backlinks to the current note via the minibuffer, use denote-find-backlink. This is an alternative to placing backlinks in a dedicated buffer (The backlinks’ buffer).

6.11 Convert ‘denote:’ links to ‘file:’ links

Sometimes the user needs to translate all ‘denote:’ link types to their ‘file:’ equivalent. This may be because some other tool does not recognise ‘denote:’ links (or other custom links types—which are a standard feature of Org, by the way). The user thus needs to (i) either make a copy of their Denote note or edit the existing one, and (ii) convert all links to the generic ‘file:’ link type that external/other programs understand.

The optional extension ‘denote-org-extras.el’ contains two commands that are relevant for this use-case:

Convert ‘denote:’ links to ‘file:’ links

The command denote-org-extras-convert-links-to-file-type goes through the buffer to find all ‘denote:’ links. It gets the identifier of the link and resolves it to the actual file system path. It then replaces the match so that the link is written with the ‘file:’ type and then the file system path. The optional search terms and/or link description are preserved (Insert link to an Org file with a further pointer to a heading).

Convert ‘file:’ links to ‘denote:’ links

The command denote-org-extras-convert-links-to-denote-type behaves like the one above. The difference is that it finds the file system path and converts it into its identifier.

6.12 Fontify links in non-Org buffers

Denote links are automatically fontified in Org buffers (Adding a single link). This means that Org recognises the link and applies the relevant properties to it to make it clickable/actionable. Other major modes, such as markdown-mode (for ‘.md’ files) or text-mode (for ‘.txt’ files) do not have this feature built into them. Users can still get the same behaviour as with Org by activating the denote-fontify-links-mode.

The denote-fontify-links-mode is a buffer-local minor mode. Users can enable it automatically in plain text files that correspond to denote notes with something like this:

(add-hook 'text-mode-hook #'denote-fontify-links-mode-maybe)

The text-mode-hook applies to all modes derived from text-mode, including markdown-mode. Though a more explicit setup does no harm:

(add-hook 'markdown-mode-hook #'denote-fontify-links-mode-maybe)

Because Org already recognises ‘denote:’ links, the function denote-fontify-links-mode-maybe will not enable the mode denote-fontify-links-mode in Org buffers.

In files whose major mode is markdown-mode, the default key binding ‘C-c C-o’ (which calls the command markdown-follow-thing-at-point) correctly resolves ‘denote:’ links. Interested users can refer to the function denote-link-markdown-follow for the implementation details.

6.13 Miscellaneous information about links

• Aliases for the linking commands
• The denote-link-description-function to format links

9.1 The denote-rename-buffer-format option

The user option denote-rename-buffer-format controls how the function denote-rename-buffer chooses the name of the buffer-to-be-renamed.

The value of this user option is a string. The following specifiers are placeholders for Denote file name components (The file-naming scheme):

• The ‘%t’ is the Denote ‘TITLE’ of the file.
• The ‘%i’ is the Denote ‘IDENTIFIER’ of the file.
• The ‘%d’ is the same as ‘%i’ (‘DATE’ mnemonic).
• The ‘%s’ is the Denote ‘SIGNATURE’ of the file.
• The ‘%k’ is the Denote ‘KEYWORDS’ of the file.
• The ‘%b’ is an indicator of whether or not the file has backlinks pointing to it. The indicator string is defined in the user option denote-rename-buffer-backlinks-indicator, alias denote-buffer-has-backlinks-string.
• The ‘%%’ is a literal percent sign.

In addition, the following flags are available for each of the specifiers:

‘0’

Pad to the width, if given, with zeros instead of spaces.

‘-’

Pad to the width, if given, on the right instead of the left.

‘<’

Truncate to the width and precision, if given, on the left.

‘>’

Truncate to the width and precision, if given, on the right.

‘^’

Convert to upper case.

‘_’

Convert to lower case.

When combined all together, the above are written thus:

%<flags><width><precision>SPECIFIER-CHARACTER

Any other string it taken as-is. Users may want, for example, to include some text that makes Denote buffers stand out, such as a ‘[D]’ prefix. Examples:

;; Use a literal [D] prefix, followed by the title and then the
;; backlinks indicator (default).
(setq denote-rename-buffer-format "[D] %t%b")

;; Customize what the backlink indicator looks like.  This two-faced
;; arrow is the default.
(setq denote-rename-buffer-backlinks-indicator  "<-->")

;; Use just the title and keywords with some emoji in between, because
;; why not?
(setq denote-rename-buffer-format "%t 🤨 %k")

;; Use the title with a literal "[D]" before it.
(setq denote-rename-buffer-format "[D] %t")

;; As above, but also add the `denote-rename-buffer-backlinks-indicator' at the end.
(setq denote-rename-buffer-format "[D] %t")

Users who need yet more flexibility are best served by writing their own function and assigning it to the denote-rename-buffer-function.

10.1 Org dynamic blocks to insert links

[ As part of version 2.3.0, all dynamic blocks are defined in the file ‘denote-org-extras.el’. The file which was once called ‘denote-org-dblock.el’ contains aliases for the new function names and displays a warning about its deprecation. There is no need to require the denote-org-extras feature because all of Denote’s Org dynamic blocks are autoloaded (meaning that they work as soon as they are used). For backward compatibility, all dynamic blocks retain their original names as an alias for the newer one. ]

The ‘denote-links’ block can be inserted at point with the command denote-org-extras-dblock-insert-links or by manually including the following in an Org file:

#+BEGIN: denote-links :regexp "YOUR REGEXP HERE" :excluded-dirs-regexp nil :sort-by-component nil :reverse-sort nil :id-only nil :include-date nil

#+END:

All the parameters except for ‘:regexp’ are optional.

The ‘denote-links’ block is also registered as an option for the command org-dynamic-block-insert-dblock.

Type ‘C-c C-x C-u’ (org-dblock-update) with point on the ‘#+BEGIN’ line to update the block.

• The ‘:regexp’ parameter is mandatory. Its value is a string and its behaviour is the same as that of the denote-add-links command (Insert links matching a regexp). Concretely, it produces a typographic list of links to files matching the giving regular expression. The value of the ‘:regexp’ parameter may also be of the form read by the rx macro (Lisp notation instead of a string), as explained in the Emacs Lisp Reference Manual (evaluate this code to read the documentation: ‘(info "(elisp) Rx Notation")’). Note that you do not need to write an actual regular expression to get meaningful results: even something like ‘_journal’ will work to include all files that have a ‘journal’ keyword.
• The ‘:excluded-dirs-regexp’ is a string that contains a word or regular expression that matches against directory files names to-be-excluded from the results. This has the same meaning as setting the denote-excluded-directories-regexp user option (Exclude certain directories from all operations). The user option has a global effect, which is overridden locally in the dynamic block. When the value of ‘:excluded-dirs-regexp’ is nil (the default), the value of denote-excluded-directories-regexp is used (which is also nil by default, meaning that all directories are included). When the value of ‘excluded-dirs-regexp’ is t or some other symbol, then the denote-excluded-directories-regexp is ignored altogether. This is useful in the scenario where the user option is set to exclude some directories but the dynamic blocks wants to lift that restriction.
• The ‘:sort-by-component’ parameter is optional. It sorts the files by the given Denote file name component. The value it accepts is an unquoted symbol among ‘title’, ‘keywords’, ‘signature’, ‘identifier’. When using the command denote-org-extras-dblock-insert-files, this parameter is automatically inserted together with the (‘:regexp’ parameter) and the user is prompted for a file name component.
• The ‘:reverse-sort’ parameter is optional. It reverses the order in which files appear in. This is meaningful even without the presence of the parameter ‘:sort-by-component’, though it also combines with it.
• The ‘:id-only’ parameter is optional. It accepts a t value, in which case links are inserted without a description text but only with the identifier of the given file. This has the same meaning as with the denote-link command and related facilities (Linking notes).
• The ‘:include-date’ parameter controls whether to display the date of the file name after the title. This is done when its value is t. By default (a nil value), no date is shown.
• An optional ‘:block-name’ parameter can be specified with a string value to add a ‘#+name’ to the results. This is useful for further processing using Org facilities (a feature that is outside Denote’s purview).

In some workflows, users may want to have a separate block to see what other links they are missing since they last updated the dynamic block. We cover that case as well (The Org dynamic block to insert missing links only).

10.2 The Org dynamic block to insert missing links only

The ‘denote-missing-links’ block is available with the command denote-org-extras-dblock-insert-missing-links. It is like the aforementioned ‘denote-links’ block, except it only lists links to files that are not present in the current buffer (Org dynamic blocks to insert links). The parameters are otherwise the same and are all optional except for ‘:regexp’:

#+BEGIN: denote-missing-links :regexp "YOUR REGEXP HERE" :excluded-dirs-regexp nil :sort-by-component nil :reverse-sort nil :id-only nil :include-date nil

#+END:

The ‘denote-missing-links’ block is also registered as an option for the command org-dynamic-block-insert-dblock.

Remember to type ‘C-c C-x C-u’ (org-dblock-update) with point on the ‘#+BEGIN’ line to update the block.

10.3 The Org dynamic block to insert backlinks

Apart from links to files matching a regular expression, we can also produce a list of backlinks to the current file. The dynamic block can be inserted at point with the command denote-org-extras-dblock-insert-backlinks or by manually writing this in an Org file:

#+BEGIN: denote-backlinks :excluded-dirs-regexp nil :sort-by-component nil :reverse-sort nil :id-only nil :this-heading-only nil :include-date nil

#+END:

The ‘denote-backlinks’ block is also registered as an option for the command org-dynamic-block-insert-dblock.

Remember to type ‘C-c C-x C-u’ (org-dblock-update) with point on the ‘#+BEGIN’ line to update the block.

The parameters recognised by this dynamic block are almost the same as that for inserting links (Org dynamic blocks to insert links). They are all optional in this case and there is no parameter expecting a regular expression for matching files to link to.

Additionally, the denote-backlinks block also recognises the ‘:this-heading-only’ parameter. It determines if the backlinks are about the file or the heading under which the dynamic block is inserted (Backlinks for Org headings). When this parameter is omitted or nil (the default), then the backlinks are about the whole file, but if this parameter has a t value then the backlinks are specifically for the heading (Insert link to an Org file with a further pointer to a heading).

10.4 Org dynamic block to insert file contents

[ As part of version 2.3.0, all dynamic blocks are defined in the file ‘denote-org-extras.el’. The file which was once called ‘denote-org-dblock.el’ contains aliases for the new function names and displays a warning about its deprecation. There is no need to require the denote-org-extras feature because all of Denote’s Org dynamic blocks are autoloaded (meaning that they work as soon as they are used). For backward compatibility, all dynamic blocks retain their original names as an alias for the newer one. ]

Denote can optionally use Org’s dynamic blocks facility to produce a section that lists entire file contents (Use Org dynamic blocks). This works by instructing Org to match a regular expression of Denote files, the same way we do with Denote links (Insert links matching a regexp).

This is useful to, for example, compile a dynamically concatenated list of scattered thoughts on a given topic, like ‘^2023.*_emacs’ for a long entry that incorporates all the notes written in 2023 with the keyword ‘emacs’.

To produce such a block, call the command denote-org-extras-dblock-insert-files or manually write the following block in an Org file and then type ‘C-c C-x C-u’ (org-dblock-update) on the ‘#+BEGIN’ line to run it (do it again to recalculate the block):

#+BEGIN: denote-files :regexp "YOUR REGEXP HERE" :sort-by-component nil :reverse-sort nil :no-front-matter nil :file-separator nil :add-links nil

#+END:

All parameters are optional except for ‘:regexp’.

The ‘denote-files’ block is also registered as an option for the command org-dynamic-block-insert-dblock.

Remember to type ‘C-c C-x C-u’ (org-dblock-update) with point on the ‘#+BEGIN’ line to update the block.

To fully control the output, include these additional optional parameters, which are described further below:

• The ‘:regexp’ parameter is mandatory. Its value is a string, representing a regular expression to match Denote file names. Its value may also be an rx expression instead of a string, as noted in the previous section (Org dynamic blocks to insert links or backlinks). Note that you do not need to write an actual regular expression to get meaningful results: even something like ‘_journal’ will work to include all files that have a ‘journal’ keyword.
• The ‘:excluded-dirs-regexp’ is a string that contains a word or regular expression that matches against directory files names to-be-excluded from the results. This has the same meaning as setting the denote-excluded-directories-regexp user option (Exclude certain directories from all operations). The user option has a global effect, which is overridden locally in the dynamic block. When the value of ‘:excluded-dirs-regexp’ is nil (the default), the value of denote-excluded-directories-regexp is used (which is also nil by default, meaning that all directories are included). When the value of ‘excluded-dirs-regexp’ is t or some other symbol, then the denote-excluded-directories-regexp is ignored altogether. This is useful in the scenario where the user option is set to exclude some directories but the dynamic blocks wants to lift that restriction.
• The ‘:sort-by-component’ parameter is optional. It sorts the files by the given Denote file name component. The value it accepts is an unquoted symbol among ‘title’, ‘keywords’, ‘signature’, ‘identifier’. When using the command denote-org-extras-dblock-insert-files, this parameter is automatically inserted together with the (‘:regexp’ parameter) and the user is prompted for a file name component.
• The ‘:reverse-sort’ parameter is optional. It reverses the order in which files appear in. This is meaningful even without the presence of the parameter ‘:sort-by-component’, though it also combines with it.

• The ‘:file-separator’ parameter is optional. If it is omitted, then Denote will use no separator between the files it inserts. If the value is t the denote-org-extras-dblock-file-contents-separator is applied at the end of each file: it introduces some empty lines and a horizontal rule between them to visually distinguish individual files. If the ‘:file-separator’ value is a string, it is used as the file separator (e.g. use ‘"\n"’ to insert just one empty new line).
• The ‘:no-front-matter’ parameter is optional. When set to a t value, Denote tries to remove front matter from the files it is inserting in the dynamic block. The technique used to perform this operation is by removing all lines from the top of the file until the first empty line. This works with the default front matter that Denote adds, but is not 100% reliable with all sorts of user-level modifications and edits to the file. When the ‘:no-front-matter’ is set to a natural number, Denote will omit that many lines from the top of the file.
• The ‘:add-links’ parameter is optional. When it is set to a t value, all files are inserted as a typographic list and are indented accordingly. The first line in each list item is a link to the file whose contents are inserted in the following lines. When the value is ‘id-only’, then links are inserted without a description text but only with the identifier of the given file. This has the same meaning as with the denote-link command and related facilities (Linking notes). Remember that Org can fold the items in a typographic list the same way it does with headings. So even long files can be presented in this format without much trouble.
• An optional ‘:block-name’ parameter can be specified with a string value to add a ‘#+name’ to the results. This is useful for further processing using Org facilities (a feature that is outside Denote’s purview).

10.5 Org dynamic block to insert Org files as headings

[ IMPORTANT NOTE: This dynamic block only works with Org files, because it has to assume the Org notation in order to insert each file’s contents as its own heading. ]

As a variation of the previously covered block that inserts file contents, we have the denote-org-extras-dblock-insert-files-as-headings command (Org dynamic block to insert file contents). It Turn the ‘#+title’ of each file into a top-level heading. Then it increments all original headings in the file by one, so that they become subheadings of what once was the ‘#+title’. Similarly, the ‘#+filetags’ of each file as tags for the top-level heading (what was the ‘#+title’).

Because of how it is meant to work, this dynamic block only works with Org files.

In its simplest form, this dynamic block looks like this, with ‘:regexp’ as the only mandatory parameter:

#+BEGIN: denote-files-as-headings :regexp "YOUR REGEXP HERE"

#+END:

Though when you use the command denote-org-extras-dblock-insert-files-as-headings you get all the parameters included:

#+BEGIN: denote-files-as-headings :regexp "YOUR REGEXP HERE" :excluded-dirs-regexp nil :sort-by-component title :reverse-sort nil :add-links t

#+END:

• The ‘:regexp’ parameter is mandatory. Its value is a string, representing a regular expression to match Denote file names. Its value may also be an rx expression instead of a string, as noted in the previous section (Org dynamic blocks to insert links or backlinks). Note that you do not need to write an actual regular expression to get meaningful results: even something like ‘_journal’ will work to include all files that have a ‘journal’ keyword.
• The ‘:excluded-dirs-regexp’ is a string that contains a word or regular expression that matches against directory files names to-be-excluded from the results. This has the same meaning as setting the denote-excluded-directories-regexp user option (Exclude certain directories from all operations). The user option has a global effect, which is overridden locally in the dynamic block. When the value of ‘:excluded-dirs-regexp’ is nil (the default), the value of denote-excluded-directories-regexp is used (which is also nil by default, meaning that all directories are included). When the value of ‘excluded-dirs-regexp’ is t or some other symbol, then the denote-excluded-directories-regexp is ignored altogether. This is useful in the scenario where the user option is set to exclude some directories but the dynamic blocks wants to lift that restriction.
• The ‘:sort-by-component’ parameter is optional. It sorts the files by the given Denote file name component. The value it accepts is an unquoted symbol among ‘title’, ‘keywords’, ‘signature’, ‘identifier’. When using the command denote-org-extras-dblock-insert-files, this parameter is automatically inserted together with the (‘:regexp’ parameter) and the user is prompted for a file name component.
• The ‘:reverse-sort’ parameter is optional. It reverses the order in which files appear in. This is meaningful even without the presence of the parameter ‘:sort-by-component’, though it also combines with it.
• The ‘:add-links’ parameter is optional. When it is set to a t value, all the top-level headings (those that were the ‘#+title’ of each file) are generated as links, pointing to the original file. This has the same meaning as with the denote-link command and related facilities (Linking notes).
• An optional ‘:block-name’ parameter can be specified with a string value to add a ‘#+name’ to the results. This is useful for further processing using Org facilities (a feature that is outside Denote’s purview).

11.1 Configure what extra prompts denote-sort-dired issues

By default, the denote-sort-dired command prompts for (i) a query to match file names, (ii) a file name component to sort by, and (iii) whether to reverse the sorting. Users can configure the latter two by modifying the user option denote-sort-dired-extra-prompts.

It accepts either a nil value or a list of symbols among sort-by-component and reverse-sort. The order those symbols appear in the list is significant, with the leftmost coming first.

In case of a nil value, those extra prompts will not happen, meaning that denote-sort-dired will fall back to using denote-sort-dired-default-sort-component and denote-sort-dired-default-reverse-sort.

Here are some examples:

;; The default extra prompts...
(setq denote-sort-dired-extra-prompts '(sort-by-component reverse-sort))

;; When using `denote-sort-dired', ask whether to reverse the sort and
;; then which file name component to sort by.  These are always done
;; after the prompt to search for files matching a regexp.
(setq denote-sort-dired-extra-prompts '(reverse-sort sort-by-component))

;; Do not prompt for a reverse sort.  Just use the value of
;; `denote-sort-dired-default-reverse-sort' (which is nil out-of-the-box).
(setq denote-sort-dired-extra-prompts '(sort-by-component))

;; Do not issue any extra prompts.  Always sort by the `title' file
;; name component and never do a reverse sort.
(setq denote-sort-dired-extra-prompts nil)
(setq denote-sort-dired-default-sort-component 'title)
(setq denote-sort-dired-default-reverse-sort nil)

11.2 Define a sorting function per component

When sorting by ‘title’, ‘keywords’, or ‘signature’ with the denote-sort-dired command, Denote will internally apply a sorting function that is specific to each component. These are subject to user configuration:

• denote-sort-title-comparison-function

• denote-sort-keywords-comparison-function

• denote-sort-signature-comparison-function

By default, all these user options use the same sorting function, namely string-collate-lessp. Users who have specific needs for any of those file name components can write their own sorting algorithms (Sort signatures that include Luhmann-style sequences).

• Sort signatures that include Luhmann-style sequences

(defun my-denote--split-luhman-sig (signature)
  "Split numbers and letters in Luhmann-style SIGNATURE string."
  (replace-regexp-in-string
   "\\([a-zA-Z]+?\\)\\([0-9]\\)" "\\1=\\2"
   (replace-regexp-in-string
    "\\([0-9]+?\\)\\([a-zA-Z]\\)" "\\1=\\2"
    signature)))

(defun my-denote--pad-sig (signature)
  "Create a new signature with padded spaces for all components"
  (combine-and-quote-strings
   (mapcar
    (lambda (x)
      (string-pad x 5 32 t))
    (split-string (my-denote--split-luhman-sig signature) "=" t))
   "="))

(defun my-denote-sort-for-signatures (sig1 sig2)
  "Return non-nil if SIG1 is smaller that SIG2.
Perform the comparison with `string<'."
  (string< (my-denote--pad-sig sig1) (my-denote--pad-sig sig2)))

;; Change the sorting function only when we sort by signature.
(setq denote-sort-signature-comparison-function #'my-denote-sort-for-signatures)

12.1 Journaling with a timer

[ Revised as part of version 2.1.0 to conform with how we now tend to the needs of users who use Denote for journaling purposes (Keep a journal or diary). ]

Sometimes journaling is done with the intent to hone one’s writing skills. Perhaps you are learning a new language or wish to communicate your ideas with greater clarity and precision. As with everything that requires a degree of sophistication, you have to work for it—write, write, write!

One way to test your progress is to set a timer. It helps you gauge your output and its quality. To use a timer with Emacs, consider the tmr package. A new timer can be set with something like this:

;; Set 10 minute timer with the given description
(tmr "10" "Practice writing in my journal")

To make this timer start as soon as a new journal entry is created with the command denote-journal-extras-new-entry, add a function to the denote-journal-extras-hook. For example:

;; Add an anonymous function, which is more difficult to modify after
;; the fact:
(add-hook 'denote-journal-extras-hook (lambda ()
                                        (tmr "10" "Practice writing in my journal")))

;; Or write a small function that you can then modify without
;; revaluating the hook:
(defun my-denote-tmr ()
  (tmr "10" "Practice writing in my journal"))

(add-hook 'denote-journal-extras-hook 'my-denote-tmr)

;; Or to make it fully featured, define variables for the duration and
;; the description and set it up so that you only need to modify
;; those:
(defvar my-denote-tmr-duration "10")

(defvar my-denote-tmr-description "Practice writing in my journal")

(defun my-denote-tmr ()
  (tmr my-denote-tmr-duration my-denote-tmr-description))

(add-hook 'denote-journal-extras-hook 'my-denote-tmr)

Once the timer elapses, stop writing and review your performance. Practice makes perfect!

Sources for tmr:

• Package name (GNU ELPA): tmr
• Official manual: https://protesilaos.com/emacs/tmr
• Change log: https://protesilaos.com/emacs/denote-changelog
• Git repo on SourceHut: https://git.sr.ht/~protesilaos/tmr
  • Mirrors:
    • GitHub: https://github.com/protesilaos/tmr
    • GitLab: https://gitlab.com/protesilaos/tmr
• Mailing list: https://lists.sr.ht/~protesilaos/tmr

14.1 Create a new note in any directory

The commands that create new files are designed to write to the denote-directory. The idea is that the linking mechanism can find any file by its identifier if it is in the denote-directory (searching the entire file system would be cumbersome).

However, these are cases where the user needs to create a new note in an arbitrary directory. The following command can do this. Put the code in your configuration file and evaluate it. Then call the command by its name with ‘M-x’.

(defun my-denote-create-note-in-any-directory ()
  "Create new Denote note in any directory.
Prompt for the directory using minibuffer completion."
  (declare (interactive-only t))
  (interactive)
  (let ((denote-directory (read-directory-name "New note in: " nil nil :must-match)))
    (call-interactively 'denote)))

14.2 Narrow the list of files in Dired

Emacs’ standard file manager (or directory editor) can read a regular expression to mark the matching files. This is the command dired-mark-files-regexp, which is bound to ‘% m’ by default. For example, ‘% m _denote’ will match all files that have the ‘denote’ keyword (Features of the file-naming scheme for searching or filtering).

Once the files are matched, the user has two options: (i) narrow the list to the matching items or (ii) exclude the matching items from the list.

For the former, we want to toggle the marks by typing ‘t’ (calls the command dired-toggle-marks by default) and then hit the letter ‘k’ (for dired-do-kill-lines). The remaining files are those that match the regexp that was provided earlier.

For the latter approach of filtering out the matching items, simply involves the use of the ‘k’ command (dired-do-kill-lines) to omit the marked files from the list.

These sequences can be combined to incrementally narrow the list. Note that dired-do-kill-lines does not delete files: it simply hides them from the current view.

Revert to the original listing with ‘g’ (revert-buffer).

For a convenient wrapper, consider this example:

(defvar prot-dired--limit-hist '()
  "Minibuffer history for `prot-dired-limit-regexp'.")

;;;###autoload
(defun prot-dired-limit-regexp (regexp omit)
  "Limit Dired to keep files matching REGEXP.

With optional OMIT argument as a prefix (\\[universal-argument]),
exclude files matching REGEXP.

Restore the buffer with \\<dired-mode-map>`\\[revert-buffer]'."
  (interactive
   (list
    (read-regexp
     (concat "Files "
             (when current-prefix-arg
               (propertize "NOT " 'face 'warning))
             "matching PATTERN: ")
     nil 'prot-dired--limit-hist)
    current-prefix-arg))
  (dired-mark-files-regexp regexp)
  (unless omit (dired-toggle-marks))
  (dired-do-kill-lines))

14.3 Use dired-virtual-mode for arbitrary file listings

Emacs’ Dired is a powerful file manager that builds its functionality on top of the Unix ‘ls’ command. As noted elsewhere in this manual, the user can update the ‘ls’ flags that Dired uses to display its contents (I want to sort by last modified, why won’t Denote let me?).

What Dired cannot do is parse the output of a result that is produced by piped commands, such as ‘ls -l | sort -t _ -k2’. This specific example targets the second underscore-separated field of the file name, per our conventions (The file-naming scheme). Conceretely, it matches the “alpha” as the sorting key in something like this:

20220929T200432--testing-file-one__alpha.txt

Consider then, how Dired will sort those files by their identifier:

20220929T200432--testing-file-one__alpha.txt
20220929T200532--testing-file-two__beta.txt
20220929T200632--testing-file-three__alpha.txt
20220929T200732--testing-file-four__beta.txt

Whereas on the command line, we can get the following:

$ ls | sort -t _ -k 2
20220929T200432--testing-file-one__alpha.txt
20220929T200632--testing-file-three__alpha.txt
20220929T200532--testing-file-two__beta.txt
20220929T200732--testing-file-four__beta.txt

This is where dired-virtual-mode shows its utility. If we tweak our command-line invocation to include ‘ls -l’, this mode can behave like Dired on the listed files. (We omit the output of the ‘-l’ flag from this tutorial, as it is too verbose.)

What we now need is to capture the output of ‘ls -l | sort -t _ -k 2’ in an Emacs buffer and then enable dired-virtual-mode. To do that, we can rely on either ‘M-x shell’ or ‘M-x eshell’ and then manually copy the relevant contents.

For the user’s convenience, I share what I have for Eshell to quickly capture the last command’s output in a dedicated buffer:

(defcustom prot-eshell-output-buffer "*Exported Eshell output*"
  "Name of buffer with the last output of Eshell command.
Used by `prot-eshell-export'."
  :type 'string
  :group 'prot-eshell)

(defcustom prot-eshell-output-delimiter "* * *"
  "Delimiter for successive `prot-eshell-export' outputs.
This is formatted internally to have newline characters before
and after it."
  :type 'string
  :group 'prot-eshell)

(defun prot-eshell--command-prompt-output ()
  "Capture last command prompt and its output."
  (let ((beg (save-excursion
               (goto-char (eshell-beginning-of-input))
               (goto-char (point-at-bol)))))
    (when (derived-mode-p 'eshell-mode)
      (buffer-substring-no-properties beg (eshell-end-of-output)))))

;;;###autoload
(defun prot-eshell-export ()
  "Produce a buffer with output of the last Eshell command.
If `prot-eshell-output-buffer' does not exist, create it.  Else
append to it, while separating multiple outputs with
`prot-eshell-output-delimiter'."
  (interactive)
  (let ((eshell-output (prot-eshell--command-prompt-output)))
    (with-current-buffer (get-buffer-create prot-eshell-output-buffer)
      (let ((inhibit-read-only t))
        (goto-char (point-max))
        (unless (eq (point-min) (point-max))
          (insert (format "\n%s\n\n" prot-eshell-output-delimiter)))
        (goto-char (point-at-bol))
        (insert eshell-output)
        (switch-to-buffer-other-window (current-buffer))))))

Bind prot-eshell-export to a key in the eshell-mode-map and give it a try (I use ‘C-c C-e’). In the produced buffer, activate the dired-virtual-mode.

14.4 Use Embark to collect minibuffer candidates

‘embark’ is a remarkable package that lets you perform relevant, context-dependent actions using a prefix key (simplifying in the interest of brevity).

For our purposes, Embark can be used to produce a Dired listing directly from the minibuffer. Suppose the current note has links to three other notes. You might use the denote-find-link command to pick one via the minibuffer. But why not turn those three links into their own Dired listing? While in the minibuffer, invoke embark-act which you may have already bound to ‘C-.’ and then follow it up with ‘E’ (for the embark-export command).

This pattern can be repeated with any list of candidates, meaning that you can narrow the list by providing some input before eventually exporting the results with Embark.

Overall, this is very powerful and you might prefer it over doing the same thing directly in Dired, since you also benefit from all the power of the minibuffer (Narrow the list of files in Dired).

14.5 Search file contents

Emacs provides built-in commands which are wrappers of standard Unix tools: ‘M-x grep’ lets the user input the flags of a grep call and pass a regular expression to the ‘-e’ flag.

The author of Denote uses this thin wrapper instead:

(defvar prot-search--grep-hist '()
  "Input history of grep searches.")

;;;###autoload
(defun prot-search-grep (regexp &optional recursive)
  "Run grep for REGEXP.

Search in the current directory using `lgrep'.  With optional
prefix argument (\\[universal-argument]) for RECURSIVE, run a
search starting from the current directory with `rgrep'."
  (interactive
   (list
    (read-from-minibuffer (concat (if current-prefix-arg
                                      (propertize "Recursive" 'face 'warning)
                                    "Local")
                                  " grep for PATTERN: ")
                          nil nil nil 'prot-search--grep-hist)
    current-prefix-arg))
  (unless grep-command
    (grep-compute-defaults))
  (if recursive
      (rgrep regexp "*" default-directory)
    (lgrep regexp "*" default-directory)))

Rather than maintain custom code, consider using the excellent ‘consult’ package: it provides commands such as consult-grep and consult-find which provide live results and are generally easier to use than the built-in commands.

14.6 Bookmark the directory with the notes

Part of the reason Denote does not reinvent existing functionality is to encourage you to learn more about Emacs. You do not need a bespoke “jump to my notes” directory because such commands do not scale well. Will you have a “jump to my downloads” then another for multimedia and so on? No.

Emacs has a built-in framework for recording persistent markers to locations. Visit the denote-directory (or any dir/file for that matter) and invoke the bookmark-set command (bound to ‘C-x r m’ by default). It lets you create a bookmark.

The list of bookmarks can be reviewed with the bookmark-bmenu-list command (bound to ‘C-x r l’ by default). A minibuffer interface is available with bookmark-jump (‘C-x r b’).

If you use the ‘consult’ package, its default consult-buffer command has the means to group together buffers, recent files, and bookmarks. Each of those types can be narrowed to with a prefix key. The package ‘consult-dir’ is an extension to ‘consult’ which provides useful extras for working with directories, including bookmarks.

14.7 Use the denote-explore package to explore your notes

Peter Prevos has developed the denote-explore package which provides four groups of Emacs commands to explore your Denote files:

Summary statistics

Count notes, attachments and keywords.

Random walks

Generate new ideas using serendipity.

Janitor

Manage your denote collection.

Visualisations

Visualise your Denote network.

The package’s documentation covers the details: https://lucidmanager.org/productivity/denote-explore/.

14.8 Use the citar-denote package for bibliography notes

Peter Prevos has produced the citar-denote package which makes it possible to write notes on BibTeX entries with the help of the citar package. These notes have the citation’s unique key associated with them in the file’s front matter. They also get a configurable keyword in their file name, making it easy to find them in Dired and/or retrieve them with the various Denote methods.

With citar-denote, the user leverages standard minibuffer completion mechanisms (e.g. with the help of the vertico and embark packages) to manage bibliographic notes and access those notes with ease. The package’s documentation covers the details: https://lucidmanager.org/productivity/bibliographic-notes-in-emacs-with-citar-denote/.

14.9 Use the consult-notes package for enhanced minibuffer interactions

The consult-denote package by me (Protesilaos) integrates Denote with Daniel Mendler’s consult package: https://github.com/protesilaos/consult-denote.

The idea is to preserve the familiar patterns of interaction with the various Denote commands but add to them an extra layer of functionality, such as the preview mechanism that Consult provides (e.g. preview the file you are about to link to).

Additionally, consult-denote defines new “sources” for the consult-buffer command. This command provides a single point of entry for buffers, recently opened files, and bookmarks. With consult-denote, it has a dedicated place for Denote-specific buffers, silos, and more (all of which are configurable).

Unlike the consult-notes package by Colin McLear, consult-denote uses the same presentation of data in the minibuffer to stay in sync with Denote and make its feature set entirely optional (Use the consult-notes package). It also only works with Denote.

14.10 Use the consult-notes package

[ Also check the consult-denote package by me (Protesilaos): Use the consult-notes package for enhanced minibuffer interactions. ]

If you are using Daniel Mendler’s consult (which is a brilliant package), you will most probably like its consult-notes extension, developed by Colin McLear. It uses the familiar mechanisms of Consult to preview the currently selected entry and to filter searches via a prefix key. For example:

(setq consult-notes-file-dir-sources
      `(("Denote Notes"  ?d ,(denote-directory))
        ("Books"  ?b "~/Documents/books/")))

With the above, ‘M-x consult-notes’ will list the files in those two directories. If you type ‘d’ and space, it narrows the list to just the notes, while ‘b’ does the same for books.

The other approach is to enable the consult-notes-denote-mode. It takes care to add the denote-directory to the sources that consult-notes reads from. Denote notes are then filtered by the ‘d’ prefix followed by a space.

The minor mode has the extra feature of reformatting the title of notes shown in the minibuffer. It isolates the ‘TITLE’ component of each note and shows it without hyphens, while presenting keywords in their own column. The user option consult-notes-denote-display-id can be set to nil to hide the identifier. Depending on how one searches through their notes, this refashioned presentation may be the best option (Features of the file-naming scheme for searching or filtering).

14.11 Use the denote-menu package

Denote’s file-naming scheme is designed to be efficient and to provide valueable meta information about the file. The cost, however, is that it is terse and harder to read, depending on how the user chooses to filter and process their notes.

To this end, the denote-menu package by Mohamed Suliman provides the convenience of a nice tabular interface for all notes. denote-menu removes the delimiters that are found in Denote file names and presents the information in a human-readable format. Furthermore, the package provides commands to interact with the list of notes, such as to filter them and to transition from the tabular list to Dired. Its documentation expands on the technicalities.

14.12 Treat your notes as a project

Emacs has a built-in library for treating a directory tree as a “project”. This means that the contents of this tree are seen as part of the same set, so commands like project-switch-to-buffer (‘C-x p b’ by default) will only consider buffers in the current project (e.g. three notes that are currently being visited).

Normally, a “project” is a directory tree whose root is under version control. For our purposes, all you need is to navigate to the denote-directory (for the shell or via Dired) and use the command-line to run this (requires the ‘git’ executable):

git init

From Dired, you can type ‘M-!’ which invokes dired-smart-shell-command and then run the git call there.

The project can then be registered by invoking any project-related command inside of it, such as project-find-file (‘C-x p f’).

It is a good idea to keep your notes under version control, as that gives you a history of changes for each file. We shall not delve into the technicalities here, though suffice to note that Emacs’ built-in version control framework or the exceptionally well-crafted ‘magit’ package will get the job done (VC can work with other backends besides Git).

14.13 Use the tree-based file prompt for select commands

Older versions of Denote had a file prompt that resembled that of the standard find-file command (bound to ‘C-x C-f’ by default). This means that it used a tree-based method of navigating the filesystem by selecting the specific directory and then the given file.

Currently, Denote flattens the file prompt so that every file in the denote-directory and its subdirectories can be matched from anywhere using the power of Emacs’ minibuffer completion (such as with the help of the orderless package in addition to built-in options).

Users who need the old behaviour on a per-command basis can define their own wrapper functions as shown in the following code block.

;; This is the old `denote-file-prompt' that we renamed to
;; `denote-file-prompt-original' for clarity.
(defun denote-file-prompt-original (&optional initial-text)
  "Prompt for file with identifier in variable `denote-directory'.
With optional INITIAL-TEXT, use it to prepopulate the minibuffer."
  (read-file-name "Select note: " (denote-directory) nil nil initial-text
                  (lambda (f)
                    (or (denote-file-has-identifier-p f)
                        (file-directory-p f)))))

;; Our wrapper command that changes the current `denote-file-prompt'
;; to the functionality of `denote-file-prompt-original' only when
;; this command is used.
(defun my-denote-link ()
  "Call `denote-link' but use Denote's original file prompt.
See `denote-file-prompt-original'."
  (interactive)
  (cl-letf (((symbol-function 'denote-file-prompt) #'denote-file-prompt-original))
    (call-interactively #'denote-link)))

14.14 Rename files with Denote in the Image Dired thumbnails buffer

Rename files with Denote using dired-preview

Just as with the denote-dired-rename-marked-files-with-keywords, we can use Denote in the Image Dired buffer (Rename multiple files at once). Here is the custom code:

(autoload 'image-dired--with-marked "image-dired")
(autoload 'image-dired-original-file-name "image-dired-util")

(defun my-denote-image-dired-rename-marked-files (keywords)
  "Like `denote-dired-rename-marked-files-with-keywords' but for Image Dired.
Prompt for KEYWORDS and rename all marked files in the Image
Dired buffer to have a Denote-style file name with the given
KEYWORDS.

IMPORTANT NOTE: if there are marked files in the corresponding
Dired buffers, those will be targeted as well.  This is not the
fault of Denote: it is how Dired and Image Dired work in tandem.
To only rename the marked thumbnails, start by unmarking
everything in Dired.  Then mark the items in Image Dired and
invoke this command."
  (interactive (list (denote-keywords-prompt)) image-dired-thumbnail-mode)
  (image-dired--with-marked
   (when-let* ((file (image-dired-original-file-name))
               (dir (file-name-directory file))
               (id (or (denote-retrieve-filename-identifier file) ""))
               (file-type (denote-filetype-heuristics file))
               (title (denote--retrieve-title-or-filename file file-type))
               (signature (or (denote-retrieve-filename-signature file) "")
               (extension (file-name-extension file t))
               (new-name (denote-format-file-name dir id keywords title extension signature))
               (default-directory dir))
     (denote-rename-file-and-buffer file new-name))))

While the my-denote-image-dired-rename-marked-files renames files in the helpful Denote-compliant way, users may still need to not prepend a unique identifier and not sluggify (hyphenate and downcase) the image’s existing file name. To this end, the following custom command can be used instead:

(defun my-image-dired-rename-marked-files (keywords)
  "Like `denote-dired-rename-marked-files-with-keywords' but for Image Dired.
Prompt for keywords and rename all marked files in the Image
Dired buffer to have Denote-style keywords, but none of the other
conventions of Denote's file-naming scheme."
  (interactive (list (denote-keywords-prompt)) image-dired-thumbnail-mode)
  (image-dired--with-marked
   (when-let* ((file (image-dired-original-file-name))
               (dir (file-name-directory file))
               (file-type (denote-filetype-heuristics file))
               (title (denote--retrieve-title-or-filename file file-type))
               (extension (file-name-extension file t))
               (kws (denote--keywords-combine keywords))
               (new-name (concat dir title "__" kws extension))
               (default-directory dir))
     (denote-rename-file-and-buffer file new-name))))

14.15 Rename files with Denote using dired-preview

The dired-preview package (by me/Protesilaos) automatically displays a preview of the file at point in Dired. This can be helpful in tandem with Denote when we want to rename multiple files by taking a quick look at their contents.

The command denote-dired-rename-marked-files-with-keywords will generate Denote-style file names based on the keywords it prompts for. Identifiers are derived from each file’s modification date (Rename multiple files at once). There is no need for any custom code in this scenario.

As noted in the section about Image Dired, the user may sometimes not need a fully fledged Denote-style file name but only append Denote-like keywords to each file name (e.g. ‘Original Name__denote_test.jpg’ instead of ‘20230710T195843--original-name__denote_test.jpg’).

Rename files with Denote in the Image Dired thumbnails buffer

In such a workflow, it is unlikely to be dealing with ordinary text files where front matter can be helpful. A custom command does not need to behave like what Denote provides out-of-the-box, but can instead append keywords to file names without conducting any further actions. We thus have:

(defun my-denote-dired-rename-marked-files-keywords-only ()
  "Like `denote-dired-rename-marked-files-with-keywords' but only for keywords in file names.

Prompt for keywords and rename all marked files in the Dired
buffer to only have Denote-style keywords, but none of the other
conventions of Denote's file-naming scheme."
  (interactive nil dired-mode)
  (if-let ((marks (dired-get-marked-files)))
      (let ((keywords (denote-keywords-prompt)))
        (dolist (file marks)
          (let* ((dir (file-name-directory file))
                 (file-type (denote-filetype-heuristics file))
                 (title (denote--retrieve-title-or-filename file file-type))
                 (extension (file-name-extension file t))
                 (kws (denote--keywords-combine keywords))
                 (new-name (concat dir title "__" kws extension)))
            (denote-rename-file-and-buffer file new-name)))
        (revert-buffer))
    (user-error "No marked files; aborting")))

14.16 Avoid duplicate identifiers when exporting Denote notes

When exporting Denote notes to, for example, an HTML or PDF file, there is a high probability that the same file name is used with a new extension. This is problematic because it creates files with duplicate identifiers. The ‘20230515T085612--example__keyword.org’ produces a ‘20230515T085612--example__keyword.pdf’. Any link to the ‘20230515T085612’ will thus break: it does not honor Denote’s expectation of finding unique identifiers. This is not the fault of Denote: exporting is done by the user without Denote’s involvement.

Org Mode and Markdown use different approaches to exporting files. No recommended method is available for plain text files as there is no standardised export functionality for this format (the user can always create a new note using the file type they want on a case-by-case basis: Convenience commands for note creation).

• Export Denote notes with Org Mode
• Export Denote notes with Markdown

(setq markdown-command "multimarkdown")

15.1 GNU ELPA package

The package is available as ‘denote’. Simply do:

M-x package-refresh-contents
M-x package-install

And search for it.

GNU ELPA provides the latest stable release. Those who prefer to follow the development process in order to report bugs or suggest changes, can use the version of the package from the GNU-devel ELPA archive. Read: https://protesilaos.com/codelog/2022-05-13-emacs-elpa-devel/.

15.2 Manual installation

Assuming your Emacs files are found in ‘~/.emacs.d/’, execute the following commands in a shell prompt:

cd ~/.emacs.d

# Create a directory for manually-installed packages
mkdir manual-packages

# Go to the new directory
cd manual-packages

# Clone this repo, naming it "denote"
git clone https://git.sr.ht/~protesilaos/denote denote

Finally, in your ‘init.el’ (or equivalent) evaluate this:

;; Make Elisp files in that directory available to the user.
(add-to-list 'load-path "~/.emacs.d/manual-packages/denote")

Everything is in place to set up the package.

19.1 Wishlist of what we can do to extend Denote

These are various ideas to extend Denote. Whether they should be in the core package or a separate extension is something we can discuss. I, Protesilaos, am happy to help anyone who wants to do any of this.

denote-consult.el

This can be a separate package that enhances or replaces the various prompts we have for files (and maybe more) by using the consult package. Consult provides the preview mechanism and can probably be used for more things, such as to define a source for Denote-only buffers in the consult-buffer command. If we need to tweak things in ‘denote.el’, I am happy to do it. For example, we could have a denote-file-prompt-function variable, which would default to denote-file-prompt (what we currently have) and would also such a hypothetical package to easily plug into what we have.

denote-embark.el

Provide integration with the embark package. This can be for doing something with the identifier/link at point. For example, it could provide an action to produce backlinks for the identifier/file we are linking to, not just the current one.

denote-transient.el

The transient package is built into Emacs 29 (Denote supports Emacs 28 though). We can use it to define an alternative to what we have for the menu bar. Perhaps this interface can used to toggle various options, such as to call denote with a different set of prompts.

A denote-directories user option

This can be either an extension of the denote-directory (accept a list of file paths value) or a new variable. The idea is to let the user define separate Denote directories which do know about the presence of each other (unlike silos). This way, a user can have an entry in ‘~/Documents/notes/’ link to something ‘~/Git/projects/’ and everything work as if the denote-directory is set to the ‘~/’ (with the status quo as of 2024-02-18 08:27 +0200).

Signatures before identifiers

This is probably going to increase the complixity of ‘denote.el’ and may not be worth pursuing. But just to explore the idea: we could have an option to rearrange file names such that the signature appears before the identifier. If we can do this in a smart way, we can probably extend the principle for all file name components. Again though, this may be too complex and not worth doing.

Encode the day in the identifier

The idea is to use some coded reference for Monday, Tuesday, etc. instead of having the generic ‘T’ in the identifier. For example, Monday is ‘A’ so the identifier for it is something like ‘20240219A101522’ instead of what we now have as ‘20240219T101522’. The old method should still be supported. Apart from changing a few regular expressions, this does not seem too complex to me. We would need a user option to opt in to such a feature. Then tweak the relevant parts. The tricky issue is to define a mapping of day names to letters/symbols that works for everyone. Do all countries have a seven-day week, for example? We need something universally applicable here.

Anything else? You are welcome to discuss these and/or add to the list.

21.1 Alternative implementations and further reading

This section covers blog posts and implementations from the Emacs community about the topic of note-taking and file organization. They may refer to some of the packages covered in the previous section or provide their custom code (Alternatives to Denote). The list is unsorted.

• José Antonio Ortega Ruiz (aka “jao”) explains a note-taking method that is simple like Denote but differs in other ways. An interesting approach overall: https://jao.io/blog/simple-note-taking.html.
• Jethro Kuan (the main ‘org-roam’ developer) explains their note-taking techniques: https://jethrokuan.github.io/org-roam-guide/. Good ideas all round, regardless of the package/code you choose to use.
• Karl Voit’s tools date2name, filetags, appendfilename, and move2archive provide a Python-based implementation to organize individual files which do not require Emacs. His approach (blog post and his presentation at GLT18) has been complemented by memacs to process e.g., the date of creation of photographs, or the log of a phone call in a format compatible to org.

[ Development note: help expand this list. ]

22.1 Why develop Denote when PACKAGE already exists?

I wrote Denote because I was using a variant of Denote’s file-naming scheme before I was even an Emacs user (I switched to Emacs from Tmux+Vim+CLI in the summer of 2019). I was originally inspired by Jekyll, the static site generator, which I started using for my website in 2016 (was on WordPress before). Jekyll’s files follow the ‘YYYY-MM-DD-TITLE.md’ pattern. I liked its efficiency relative to the unstructured mess I had before. Eventually, I started using that scheme outside the confines of my website’s source code. Over time I refined it and here we are.

Note-taking is something I take very seriously, as I am a prolific writer (just check my website, which only reveals the tip of the iceberg). As such, I need a program that does exactly what I want and which I know how to extend. I originally tried to use Org capture templates to create new files with a Denote-style file-naming scheme but never managed to achieve it. Maybe because org-capture has some hard-coded assumptions or I simply am not competent enough to hack on core Org facilities. Whatever the case, an alternative was in order.

The existence of PACKAGE is never a good reason for me not to conduct my own experiments for recreational, educational, or practical purposes. When the question arises of “why not contribute to PACKAGE instead?” the answer is that without me experimenting in the first place, I would lack the skills for such a task. Furthermore, contributing to another package does not guarantee I get what I want in terms of workflow.

Whether you should use Denote or not is another matter altogether: choose whatever you want.

22.2 Why not rely exclusively on Org?

I think Org is one of Emacs’ killer apps. I also believe it is not the right tool for every job. When I write notes, I want to focus on writing. Nothing more. I thus have no need for stuff like org-babel, scheduling to-do items, clocking time, and so on. The more “mental dependencies” you add to your workflow, the heavier the burden you carry and the less focused you are on the task at hand: there is always that temptation to tweak the markup, tinker with some syntactic construct, obsess about what ought to be irrelevant to writing as such.

In technical terms, I also am not fond of Org’s code base (I understand why it is the way it is—just commenting on the fact). Ever tried to read it? You will routinely find functions that are tens-to-hundreds of lines long and have all sorts of special casing. As I am not a programmer and only learnt to write Elisp through trial and error, I have no confidence in my ability to make Org do what I want at that level, hence ‘denote’ instead of ‘org-denote’ or something.

Perhaps the master programmer is one who can deal with complexity and keep adding to it. I am of the opposite view, as language—code included—is at its communicative best when it is clear and accessible.

Make no mistake: I use Org for the agenda and also to write technical documentation that needs to be exported to various formats, including this very manual.

22.3 Why care about Unix tools when you use Emacs?

My notes form part of my longer-term storage. I do not want to have to rely on a special program to be able to read them or filter them. Unix is universal, at least as far as I am concerned.

Denote streamlines some tasks and makes things easier in general, which is consistent with how Emacs provides a layer of interactivity on top of Unix. Still, Denote’s utilities can, in principle, be implemented as POSIX shell scripts (minus the Emacs-specific parts like fontification in Dired or the buttonization of links).

Portability matters. For example, in the future I might own a smartphone, so I prefer not to require Emacs, Org, or some other executable to access my files on the go.

Furthermore, I might want to share those files with someone. If I make Emacs a requirement, I am limiting my circle to a handful of relatively advanced users.

Please don’t misinterpret this: I am using Emacs full-time for my computing and maintain a growing list of packages for it. This is just me thinking long-term.

22.4 Why many small files instead of few large ones?

I have read that Org favours the latter method. If true, I strongly disagree with it because of the implicit dependency it introduces and the way it favours machine-friendliness over human-readability in terms of accessing information. Notes are long-term storage. I might want to access them on (i) some device with limited features, (ii) print on paper, (iii) share with another person who is not a tech wizard.

There are good arguments for few large files, but all either prioritize machine-friendliness or presuppose the use of sophisticated tools like Emacs+Org.

Good luck using ‘less’ on a generic TTY to read a file with a zillion words, headings, sub-headings, sub-sub-headings, property drawers, and other constructs! You will not get the otherwise wonderful folding of headings the way you do in Emacs—do not take such features for granted.

My point is that notes should be atomic to help the user—and potentially the user’s family, friends, acquaintances—make sense of them in a wide range of scenaria. The more program-agnostic your file is, the better for you and/or everyone else you might share your writings with.

Human-readability means that we optimize for what matters to us. If (a) you are the only one who will ever read your notes, (b) always have access to good software like Emacs+Org, (c) do not care about printing on paper, then Denote’s model is not for you. Maybe you need to tweak some org-capture template to append a new entry to one mega file (I do that for my Org agenda, by the way, as I explained before about using the right tool for the job).

22.5 Does Denote perform well at scale?

Denote does not do anything fancy and has no special requirements: it uses standard tools to accomplish ordinary tasks. If Emacs can cope with lots of files, then that is all you need to know: Denote will work.

To put this to the test, Peter Prevos is running simulations with R that generate large volumes of notes. You can read the technicalities here: https://lucidmanager.org/productivity/testing-denote-package/. Excerpt:

Using this code I generated ten thousands notes and used this to test the Denote package to see it if works at a large scale. This tests shows that Prot’s approach is perfectly capable of working with thousands of notes.

Of course, we are always prepared to make refinements to the code, where necessary, without compromising on the project’s principles.

22.6 I add TODOs to my notes; will many files slow down the Org agenda?

Yes, many files will slow down the agenda due to how that works. Org collects all files specified in the org-agenda-files, searches through their contents for timestamped entries, and then loops through all days to determine where each entry belongs. The more days and more files, the longer it takes to build the agenda. Doing this with potentially hundreds of files will have a noticeable impact on performance.

This is not a deficiency of Denote. It happens with generic Org files. The way the agenda is built is heavily favoring the use of a single file that holds all your timestamped entries (or at least a few such files). Tens or hundreds of files are inefficient for this job. Plus doing so has the side-effect of making Emacs open all those files, which you probably do not need.

If you want my opinion though, be more forceful with the separation of concerns. Decouple your knowledge base from your ephemeral to-do list: Denote (and others) can be used for the former, while you let standard Org work splendidly for the latter—that is what I do, anyway.

Org has a powerful linking facility, whether you use org-store-link or do it via an org-capture template. If you want a certain note to be associated with a task, just store the task in a single ‘tasks.org’ (or however you name it) and link to the relevant context.

Do not mix your knowledge base with your to-do items. If you need help figuring out the specifics of this workflow, you are welcome to ask for help in our relevant channels (Contributing).

22.7 I want to sort by last modified in Dired, why won’t Denote let me?

Denote does not control how Dired sorts files. I encourage you to read the manpage of the ‘ls’ executable. It will help you in general, while it applies to Emacs as well via Dired. The gist is that you can update the ‘ls’ flags that Dired uses on-the-fly: type ‘C-u M-x dired-sort-toggle-or-edit’ (‘C-u s’ by default) and append ‘--sort=time’ at the prompt. To reverse the order, add the ‘-r’ flag. The user option dired-listing-switches sets your default preference.

For an on-demand sorted and filtered Dired listing of Denote files, use the command denote-sort-dired (Sort files by component).

22.8 How do you handle the last modified case?

Denote does not insert any meta data or heading pertaining to edits in the file. I am of the view that these either do not scale well or are not descriptive enough. Suppose you use a “lastmod” heading with a timestamp: which lines where edited and what did the change amount to?

This is where an external program can be helpful. Use a Version Control System, such as Git, to keep track of all your notes. Every time you add a new file, record the addition. Same for post-creation edits. Your VCS will let you review the history of those changes. For instance, Emacs’ built-in version control framework has a command that produces a log of changes for the current file: ‘M-x vc-print-log’, bound to ‘C-x v l’ by default. From there one can access the corresponding diff output (use ‘M-x describe-mode’ (‘C-h m’) in an unfamiliar buffer to learn more about it). With Git in particular, Emacs users have the option of the all-round excellent ‘magit’ package.

In short: let Denote (or equivalent) create notes and link between them, the file manager organise and provide access to files, search programs deal with searching and narrowing, and version control software handle the tracking of changes.

22.9 Why are some Org links opening outside Emacs?

Org has its own mechanism to determine how best to open a link. This affects the ‘file:’ link type, but also the ‘denote:’ one (which is designed to be as close to ‘file:’ as possible).

When following a link, Org usually displays the data in an Emacs buffer, though it might launch an external application instead. The idea is to use a specialised program when that is relevant, such as to display a video. Though there can be scenaria the user does not like, such as when Org decides to load ‘.md’ or ‘.html’ files with an external app. To compound the problem, users can name any file type using the Denote file-naming scheme, including images, PDFs, videos, and more (Renaming files).

To instruct Org to stay in Emacs for such cases, the user needs to modify the variable org-file-apps, which is not specific to Denote. As one use-case, org-file-apps associates a regular expression to match file names with a method on how to display them (do ‘M-x describe-variable’ and then search for org-file-apps to read its documentation). Thus, the user can use something like the following in their Org or Denote configuration:

;; Tell Org to use Emacs when opening files that end in .md
(add-to-list 'org-file-apps '("\\.md\\'" . emacs))

;; Do the same for .html
(add-to-list 'org-file-apps '("\\.html\\'" . emacs))

Each of these adds a new entry to the existing value of that user option. Replace ‘md’ or ‘html’ with the desired file type extension.

22.10 Speed up backlinks’ buffer creation?

Denote leverages the built-in ‘xref’ library to search for the identifier of the current file and return any links to it. For users of Emacs version 28 or higher, there exists a user option to specify the program that performs this search: xref-search-program. The default is ‘grep’, which can be slow, though one may opt for ‘ugrep’, ‘ripgrep’, or even specify something else (read the doc string of that user option for the details).

Try either for these for better results:

(setq xref-search-program 'ripgrep)

;; OR

(setq xref-search-program 'ugrep)

To use whatever executable is available on your system, use something like this:

;; Prefer ripgrep, then ugrep, and fall back to regular grep.
(setq xref-search-program
      (cond
       ((or (executable-find "ripgrep")
            (executable-find "rg"))
        'ripgrep)
       ((executable-find "ugrep")
        'ugrep)
       (t
        'grep)))

22.11 Why do I get “Search failed with status 1” when I search for backlinks?

Denote uses (emacs)Emacs’ Xref to find backlinks. Xref requires xargs and one of grep or ripgrep, depending on your configuration.

This is usually not an issue on *nix systems, but the necessary executables are not available on Windows Emacs distributions. Please ensure that you have both xargs and either grep or ripgrep available within your PATH environment variable.

If you have git on Windows installed, then you may use the following code (adjust the git’s installation path if necessary):

(setenv "PATH" (concat (getenv "PATH") ";" "C:\\Program Files\\Git\\usr\\bin"))

22.12 Why do I get a double ‘#+title’ in Doom Emacs?

Doom Emacs provides a set of bespoke templates for Org. One of those prefills any new Org file with a ‘#+title’ field. So when Denote creates a new Org file and inserts front matter to it, it inevitably adds an extra title to the existing one.

This is not a Denote problem. We can only expect a new file to be empty by default. Check how to disable the relevant module in your Doom Emacs configuration file.

B.1 Function index

B.2 Variable index

B.3 Concept index