GNU-devel ELPA - guess-language

(require 'guess-language)

;; Optionally:
(setq guess-language-languages '(en de))
(setq guess-language-min-paragraph-length 35)

guess-language-languages defines the candidate languages that should be considered. It is recommended to only include languages that are actually used because this improves performance. Languages are identified using ISO 639-1 codes (see table below).

guess-language-min-paragraph-length specifies the minimal length that a paragraph needs to have before guess-language-mode starts guessing. Based on some informal tests texts shorter than 30 characters are not enough to give good results. However, above 40 characters the algorithm performs well. Of course, these numbers depend on the target language (some are easier to detect than others) and on the (number of) candidate languages that are considered. (Open the files in the directory testdata and do M-x guess-language-mark-lines to see for yourself.)

For each language, there is a default Ispell dictionary that guess-language-mode tries to use. However, for some languages there are several dictionaries available and guess-language can’t know which one you’d like to use. For example, there are several different dictionaries for German and for English. If the dictionary that guess-language-mode uses by default is not present, you will get an error message like the following:

Error in post-command-hook (flyspell-post-command-hook): (error "Undefined dictionary: en")

In this case, use the variable guess-language-langcodes to tell guess-language-mode which dictionary should be used instead. For example, use the following definition if you want to use British English and Swiss German:

(setq guess-language-langcodes
  '((en . ("en_GB" "English" "🇬🇧" "English"))
    (de . ("de_CH" "German" "🇨🇭" "Swiss German"))))

The key is a symbol specifying the ISO 639-1 code of the language. The values is a list with four elements. The first is the name of the dictionary that should be used by the spell-checker (e.g., what you would enter when setting the language with ispell-change-dictionary). The second element is the name of the language setting that should be used with typo-mode. If a language is not supported by typo-mode, that value is nil. The third element is a string for displaying the current language in the mode line. This could be text or a Unicode flag symbol (displayed as color emoji starting from Emacs 28.1). The last element is the name of the language for display in the mini buffer.

For a list of all dictionaries available for spell-checking, use the following:

(mapcar 'car ispell-dictionary-alist)

Languages that are currently supported by guess-language-mode:

While changing the spell-checker’s dictionary is the main purpose of guess-language, there are other things that a user might want to do when a new language is detected, for instance, a user might want to change the input method. Things like that can be easily achieved by adding custom functions to the hook guess-language-after-detection-functions. Functions on this hook take three arguments:

Template:

(defun my-custom-function (lang beginning end)
  (do-something))

(add-hook 'guess-language-after-detection-functions #'my-custom-function)

The code snipped below illustrates how guess-language can be configured to automatically change the voice used by the text-to-speech engine Festival (install festival.el for this to work):

(defun guess-language-switch-festival-function (lang beginning end)
  "Switch the voice used by festival.

LANG is the ISO 639-1 code of the language (as a
symbol).  BEGINNING and END are the endpoints of the region in
which LANG was detected but these are ignored."
  (when (and (featurep 'festival)
	     (festivalp))
    (pcase lang
      ('en (festival-voice-english-female))
      ('de (festival-voice-german-female)))))

(add-hook 'guess-language-after-detection-functions #'guess-language-switch-festival-function)

The pcase needs to be modified to use the voices that are installed on your system. Refer to the documentation of Festival for details.

Synosaurus is an Emacs package providing access to a German or English thesaurus. Using the code below the language of the thesaurus is automatically changed to the language of the current paragraph. Refer to the documentation of Synosaurus for details.

(defun guess-language-switch-synosaurus (lang beginning end)
  "Switch the thesaurus language.

LANG is the ISO 639-1 code of the language (as a
symbol).  BEGINNING and END are the endpoints of the region in
which LANG was detected.  These are ignored."
  (when (featurep 'synosaurus)
    (pcase lang
      ('en (setq synosaurus-backend 'synosaurus-backend-wordnet))
      ('de (setq synosaurus-backend 'synosaurus-backend-openthesaurus)))))

(add-hook 'guess-language-after-detection-functions #'guess-language-switch-synosaurus)